Mikrotik IPTV - 2 mAP detrás de routers de operadora

Cualquiera de los dos motivos te puede tirar el túnel. Wireguard siempre con su MTU por defecto, 1420, puesto que se come 80 bytes de overhead. Y, si quieres tener la misma clave pública, genera la interfaz wireguard especificando la clave privada, si aún la conservas.

Lo único que hecho de menos de la config es el direccionamiento de la interfaz wireguard. Según el resto del export, te faltaría esto:
Código:
/ip address
add address=172.17.0.1/30 interface=wg-sts-iptv

Saludos!
 
añadido! El túnel todavía no levanta, pero veremos qué pasa cuando esta tarde cambie en Paco los parámetros.

Gracias de nuevo!
 
Solo por hacer doble check de la configuración que voy a cargar en Paco (no tiene nada fuera de lo común, únicamente ether3 añadido para hacer de switch y dar una salida a internet adicional por ese puerto).

Antes de volver a cargar la configuración desde 0, guardaré la private key para que matchee la public que tengo en Pepe.

Código:
#######################################
########## ROUTER DE PACO #############
#######################################

############## VARIABLES ##############
:local puertoWireguardPepe "54321"
:local publicKeyWireguardPepe "2V8wLdPUlRl+M2V6bKyA5oSK8Rv5V2RfbySq7q1RanQ="
:local subredLanPepe "192.168.88.0/24"
:local direccionDDNSPepe "DDNSPEPE"
:local nombreRouterPaco "gorron"

############## WIREGUARD ##############
# Creamos una nueva interfaz para este propósito
# Obviamos el puerto, no lo vamos a usar
/interface/wireguard
add name=wg-sts-iptv
# Creamos un nuevo peer que representa el router de Pepe
# La public key la cogemos de la interfaz
# wireguard-sts-iptv del router remoto.
# Modificamos el endpoint por la dirección cloud de Pepe
/interface/wireguard/peers
add allowed-address=0.0.0.0/0 endpoint-address=\
  $direccionDDNSPepe endpoint-port=$puertoWireguardPepe \
  interface=wg-sts-iptv \
  public-key=$publicKeyWireguardPepe \
  persistent-keepalive=25s

######### EOIP SOBRE LAS /30 ##########
# Creamos un nuevo túnel EoIP
/interface/eoip
add local-address=172.17.0.2 name=eoip-iptv \
  remote-address=172.17.0.1 tunnel-id=0 mtu=1500

############ NUEVOS BRIDGES ###########
# Creamos el nuevo bridge con igmp-snooping para IPTV,
# además del bridge normal del router que usaremos
# como interfaz de loopback, para administración
/interface/bridge
add admin-mac=[/interface/ethernet/get ether2 mac-address] \
    auto-mac=no name=bridge-lo
add igmp-snooping=yes name=bridge-iptv
# Metemos cada puerto en su sitio, ether1 = router del operador
# ether2 = lo reservamos como puerto de administración
# si queremos aprovechar todos los puertos como switch,
# metermos todos ellos en el bridge iptv +  el túnel EoIP
/interface/bridge/port
add bridge=bridge-lo interface=ether2
add bridge=bridge-iptv interface=ether1
add bridge=bridge-iptv interface=ether3
add bridge=bridge-iptv interface=eoip-iptv

########### DIRECCIONAMIENTO ##########
# Direccionamos el bridge loopback y el túnel
/ip/address
add address=192.168.79.1/24 interface=bridge-lo
add address=172.17.0.2/30 interface=wg-sts-iptv

########## DHCP ADMINISTRACION  #######
/ip/pool
add name=pool-lo ranges=192.168.79.2-192.168.79.254
/ip/dhcp-server
add address-pool=pool-lo interface=bridge-lo name=dhcp-lo
/ip/dhcp-server/network
add address=192.168.79.0/24 gateway=192.168.79.1

####### CREAMOS LA INTERFAZ WAN #######
# Nuestra WAN = bridge-iptv, como switch que somos
# Levantaremos un cliente DHCP para obtner IP
# y salida a internet, para poder llamar a casa
# obtendremos una ruta por defecto y un DNS
/ip/dhcp-client
add interface=bridge-iptv

########## DNS SERVER BACKUP ##########
# Le damos  un DNS de backup, por si nos
# falla el que entregue el cliente DHCP
/ip/dns
set servers=1.1.1.1,1.0.0.1

############ RUTA ESTÁTICA ############
# Esto le permitirá a Pepe administrar
# el router gorrón en remoto. Suponemos
# 192.168.88.0/24 segmento pricipal LAN
# de Pepe el cual alcanzamos al otro lado
# del túnelWireGuard, 172.17.0.1
/ip/route
add dst-address=$subredLanPepe gateway=172.17.0.1

/ip/cloud
set ddns-enabled=yes
 
Correcto. En un principio, no tiene más.

Saludos!
 
Correcto. En un principio, no tiene más.

Saludos!
Funciona!! Finalmente he ido a casa de Paco, ajustado todo de nuevo y todo se ha levantado!!

Lo que me chirría, es que en el lado de Pepe, el decodificador dice que tiene problemas de red: da error en una actualización, y no se carga correctamente la pantalla principal (dice que tiene problemas de red continuamente).

¿Sabes a qué puede ser debido?

Gracias!
 
qué raro... De hecho ahora se ha caído el túnel y no hay manera de levantarlo. He probado reiniciando tanto Pepe, como Paco remotamente y nada.
 
haciendo un par de reinicios en Paco, he conseguido que vuelva a levantar (creo que hace falta poner un script que automatice esto). Pero el deco "no se actualiza", es un poco raro..


PACO
Código:
#######################################
########## ROUTER DE PACO #############
#######################################

############## VARIABLES ##############
:local puertoWireguardPepe "54321"
:local publicKeyWireguardPepe "2V8wLdPUlRl+M2V6bKyA5oSK8Rv5V2RfbySq7q1RanQ="
:local subredLanPepe "192.168.88.0/24"
:local direccionDDNSPepe "DDNSPEPE"
:local nombreRouterPaco "gorron"

############## WIREGUARD ##############
# Creamos una nueva interfaz para este propósito
# Obviamos el puerto, no lo vamos a usar
/interface/wireguard
add name=wg-sts-iptv
# Creamos un nuevo peer que representa el router de Pepe
# La public key la cogemos de la interfaz
# wireguard-sts-iptv del router remoto.
# Modificamos el endpoint por la dirección cloud de Pepe
/interface/wireguard/peers
add allowed-address=0.0.0.0/0 endpoint-address=\
  $direccionDDNSPepe endpoint-port=$puertoWireguardPepe \
  interface=wg-sts-iptv \
  public-key=$publicKeyWireguardPepe \
  persistent-keepalive=25s

######### EOIP SOBRE LAS /30 ##########
# Creamos un nuevo túnel EoIP
/interface/eoip
add local-address=172.17.0.2 name=eoip-iptv \
  remote-address=172.17.0.1 tunnel-id=0 mtu=1500

############ NUEVOS BRIDGES ###########
# Creamos el nuevo bridge con igmp-snooping para IPTV,
# además del bridge normal del router que usaremos
# como interfaz de loopback, para administración
/interface/bridge
add admin-mac=[/interface/ethernet/get ether2 mac-address] \
    auto-mac=no name=bridge-lo
add igmp-snooping=yes name=bridge-iptv
# Metemos cada puerto en su sitio, ether1 = router del operador
# ether2 = lo reservamos como puerto de administración
# si queremos aprovechar todos los puertos como switch,
# metermos todos ellos en el bridge iptv +  el túnel EoIP
/interface/bridge/port
add bridge=bridge-lo interface=ether2
add bridge=bridge-iptv interface=ether1
add bridge=bridge-iptv interface=ether3
add bridge=bridge-iptv interface=eoip-iptv

########### DIRECCIONAMIENTO ##########
# Direccionamos el bridge loopback y el túnel
/ip/address
add address=192.168.79.1/24 interface=bridge-lo
add address=172.17.0.2/30 interface=wg-sts-iptv

########## DHCP ADMINISTRACION  #######
/ip/pool
add name=pool-lo ranges=192.168.79.2-192.168.79.254
/ip/dhcp-server
add address-pool=pool-lo interface=bridge-lo name=dhcp-lo
/ip/dhcp-server/network
add address=192.168.79.0/24 gateway=192.168.79.1

####### CREAMOS LA INTERFAZ WAN #######
# Nuestra WAN = bridge-iptv, como switch que somos
# Levantaremos un cliente DHCP para obtner IP
# y salida a internet, para poder llamar a casa
# obtendremos una ruta por defecto y un DNS
/ip/dhcp-client
add interface=bridge-iptv

########## DNS SERVER BACKUP ##########
# Le damos  un DNS de backup, por si nos
# falla el que entregue el cliente DHCP
/ip/dns
set servers=1.1.1.1,1.0.0.1

############ RUTA ESTÁTICA ############
# Esto le permitirá a Pepe administrar
# el router gorrón en remoto. Suponemos
# 192.168.88.0/24 segmento pricipal LAN
# de Pepe el cual alcanzamos al otro lado
# del túnelWireGuard, 172.17.0.1
/ip/route
add dst-address=$subredLanPepe gateway=172.17.0.1

/ip/cloud
set ddns-enabled=yes

PEPE
Código:
# aug/30/2022 18:08:08 by RouterOS 7.4.1
# software id = 7T0T-H19V
#
# model = RB750r2
/interface bridge
add admin-mac=DC:2C:6E:C0:0A:C2 auto-mac=no comment=defconf name=bridge
add igmp-snooping=yes name=bridge-iptv
/interface eoip
add local-address=172.17.0.1 mac-address=FE:19:6C:10:65:55 mtu=1500 name=\
    eoip-iptv remote-address=172.17.0.2 tunnel-id=0
/interface wireguard
add listen-port=54321 mtu=1420 name=wg-sts-iptv
/interface list
add comment=defconf name=WAN
add comment=defconf name=LAN
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip pool
add name=default-dhcp ranges=192.168.88.10-192.168.88.254
/ip dhcp-server
add address-pool=default-dhcp interface=bridge name=defconf
/interface bridge port
add bridge=bridge comment=defconf interface=ether2
add bridge=bridge comment=defconf interface=ether3
add bridge=bridge comment=defconf interface=ether4
add bridge=bridge-iptv interface=ether5
add bridge=bridge-iptv interface=eoip-iptv
/ip neighbor discovery-settings
set discover-interface-list=LAN
/interface list member
add comment=defconf interface=bridge list=LAN
add comment=defconf interface=ether1 list=WAN
/interface wireguard peers
add allowed-address=172.17.0.2/32 comment=gorron-iptv endpoint-address=\
    DDNSPACO endpoint-port=12345 interface=wg-sts-iptv \
    persistent-keepalive=25s public-key=\
    "Asl16wYnn1fscyES9Jd6xvNMDYV+EhJvOf05eWV0O1U="
/ip address
add address=192.168.88.1/24 comment=defconf interface=bridge network=\
    192.168.88.0
add address=172.17.0.1/30 interface=wg-sts-iptv network=172.17.0.0
/ip cloud
set ddns-enabled=yes ddns-update-interval=10m
/ip dhcp-client
add comment=defconf interface=ether1
/ip dhcp-server network
add address=192.168.88.0/24 comment=defconf dns-server=192.168.88.1 gateway=\
    192.168.88.1
/ip dns
set allow-remote-requests=yes
/ip dns static
add address=192.168.88.1 comment=defconf name=router.lan
/ip firewall nat
add action=masquerade chain=srcnat comment="defconf: masquerade" \
    ipsec-policy=out,none out-interface-list=WAN
/system clock
set time-zone-name=Europe/Madrid
/tool mac-server
set allowed-interface-list=LAN
/tool mac-server mac-winbox
set allowed-interface-list=LAN


Gracias!
 
he probado a hacer un reset al deco, y ahora sigue conectado, pero dice "No se puede descargar el software del equipo", y yo veo tráfico moviéndose por Wireguard y EoIP... Tal vez sea porque la primera vez deba conectarlo directamente en casa de Paco?
 
En un principio está bien, aunque lo primero no es el export. Y lo dicho, como ninguno de los dos extremos controla la IP pública, asegúrate de que el DDNS se actualiza desde equipos que estén directamente en contacto con la IP pública.

Saludos!
 
En un principio está bien, aunque lo primero no es el export. Y lo dicho, como ninguno de los dos extremos controla la IP pública, asegúrate de que el DDNS se actualiza desde equipos que estén directamente en contacto con la IP pública.

Saludos!

No es el export porque no estoy en casa de Paco, pero es la configuración que precargué y solamente le añadí los datos faltantes...

No entiendo por qué el deco entonces dice que no puede descargar el software (cuando sí tiene conectividad)!! Qué rabia!
 
Está el túnel EoIP con el flag "RS" ? Si no está así, no hay conectividad, por mucho que veas paquetes ir y venir.

Saludos!
 
efectivamente tiene el flag... ¿Puede ser que el deco tenga que actualizarse en casa de Paco por algo de DRM? A priori no tiene mucho sentido, pero no sé..

Mañana lo llevaré y conectaré allí.

Muchas gracias por toda la ayuda!
 
efectivamente tiene el flag... ¿Puede ser que el deco tenga que actualizarse en casa de Paco por algo de DRM? A priori no tiene mucho sentido, pero no sé..

Mañana lo llevaré y conectaré allí.

Muchas gracias por toda la ayuda!
Prueba una cosa. Apaga el deco, sácale la corriente y desenchufa sus cables y, pasado 15min, lo vuelves a conectar.

Sino, te lo llevas mañana anca Paco.

Saludos!
 
he hecho lo que me has dicho + reinicio remoto del router del operador de Paco y... Maravilla.

Eres un crack!!! Mil gracias por toda la ayuda
 
Vuelvo a la carga con nuevas dudas!
Estoy intentando montar Pepe, con un mikrotik hAP AC2. El esquema funcionaría tal que así: Pepe conectado por Wifi al router del operador (usando banda 5GHz; interface wlan2); Deco conectado a Pepe a través de ether5.

La cuestión está en que no consigo hacer que wlan2 sea PoE... Entiendo que sería un formato "station pseudobridge", y en quickstart he llegado a introducir la clave de la red (aunque en el export no me sale), y no consigo que haya internet en ninguno de los ether...

Este sería el export (faltaría deshabilitar wlan1):

Código:
# sep/08/2022 21:58:12 by RouterOS 7.5
# software id = 90FI-7IYR
#
# model = RBD52G-5HacD2HnD
/interface bridge
add admin-mac=2C:C8:1B:C0:27:C0 auto-mac=no comment=defconf name=bridge
add igmp-snooping=yes name=bridge-iptv
/interface wireless
set [ find default-name=wlan1 ] band=2ghz-b/g/n channel-width=20/40mhz-XX \
    disabled=no distance=indoors frequency=auto installation=indoor mode=\
    ap-bridge ssid=MikroTik-C027C4 wireless-protocol=802.11
set [ find default-name=wlan2 ] band=5ghz-a/n/ac channel-width=\
    20/40/80mhz-eCee disabled=no distance=indoors frequency=5280 \
    installation=indoor mode=station-pseudobridge ssid=WLAND \
    wireless-protocol=802.11
/interface eoip
add mac-address=02:0C:55:8A:1A:46 mtu=1500 name=eoip-iptv remote-address=\
    172.17.1.2 tunnel-id=1
/interface wireguard
add listen-port=54321 mtu=1420 name=wg-sts-iptv
/interface list
add comment=defconf name=WAN
add comment=defconf name=LAN
/interface lte apn
set [ find default=yes ] ip-type=ipv4 use-network-apn=no
/interface wireless security-profiles
set [ find default=yes ] authentication-types=wpa-psk,wpa2-psk group-ciphers=\
    tkip,aes-ccm mode=dynamic-keys supplicant-identity=MikroTik \
    unicast-ciphers=tkip,aes-ccm
/ip pool
add name=default-dhcp ranges=192.168.88.10-192.168.88.254
/ip dhcp-server
add address-pool=default-dhcp interface=bridge name=defconf
/interface bridge port
add bridge=bridge comment=defconf ingress-filtering=no interface=ether2
add bridge=bridge comment=defconf ingress-filtering=no interface=ether3
add bridge=bridge comment=defconf ingress-filtering=no interface=ether4
add bridge=bridge comment=defconf ingress-filtering=no interface=wlan1
add bridge=bridge-iptv interface=ether5
add bridge=bridge-iptv interface=eoip-iptv
/ip neighbor discovery-settings
set discover-interface-list=LAN
/ip settings
set max-neighbor-entries=8192
/ipv6 settings
set disable-ipv6=yes max-neighbor-entries=8192
/interface list member
add comment=defconf interface=bridge list=LAN
add comment=defconf interface=wlan2 list=WAN
/interface ovpn-server server
set auth=sha1,md5
/interface wireguard peers
add allowed-address=172.17.1.2/32 endpoint-address=CASAPACO \
    endpoint-port=12345 interface=wg-sts-iptv public-key=\
    "2V8wLdPUlRl+M2V6bKyA5oSK8Rv5V2RfbySq7q1RanS="
/ip address
add address=192.168.88.1/24 comment=defconf interface=bridge network=\
    192.168.88.0
add address=172.17.1.1/30 interface=wg-sts-iptv network=172.17.1.0
/ip dhcp-client
add comment=defconf interface=wlan2
/ip dhcp-server network
add address=192.168.88.0/24 comment=defconf dns-server=192.168.88.1 gateway=\
    192.168.88.1
/ip dns
set allow-remote-requests=yes
/ip dns static
add address=192.168.88.1 comment=defconf name=router.lan
/ip firewall nat
add action=masquerade chain=srcnat comment="defconf: masquerade" \
    ipsec-policy=out,none out-interface-list=WAN
/system clock
set time-zone-name=Europe/Madrid
/tool mac-server
set allowed-interface-list=LAN
/tool mac-server mac-winbox
set allowed-interface-list=LAN

Gracias!!
EDIT: añadido dhcp a wlan2, pero sigue sin funcionar..
 
Última edición:
Wlan2 = station, fuera de ningún bridge y metido en la lista WAN. Con eso te vale.

Saludos!
 
Hola chicos.

Aprovecho este hilo para no estar abriendo más con el mismo tema. Si no procede, me lo decís y abro otro aparte.

Mi escenario de pruebas es el siguiente. Adelanto que no tengo tele para probar, sólo me interesa por los túneles WireGuard (de momento jeje).

Paco tiene un RB750Gr3 detrás del router del ISP (Vodafone), Pepe1 tiene un RB3011UiAS controlando toda su red y Pepe2 un hAP Lite que está detrás del router que le puso su compañía. Ninguno tiene CG-NAT.

He hecho un cutre-paint para ilustrar esto y luego lo explico un poco más:

1662828101827.png

Partimos de que en Paco no tocamos absolutamente nada. No tenemos comunicación bidireccional y él se encarga de llamar a los Pepes.

He creado dos túneles WireGuard con sus respectivos EoIP. El de Pepe1 tiene el Tunnel ID 0 y el de Pepe2 el Tunnel ID 1.

Paco1 está funcionando perfectamente.

He abierto el puerto para WireGuard en el router del ISP de Paco2 y su Mikrotik tiene una IP fija (la 192.168.0.10 en concreto). No hay manera de levantar el túnel.

Los DDNS están actualizados y comprobados (entre Paco y Pepe1 funciona).

He repasado la config y comparado la de Pepe2 con la de Pepe1 no sé cuántas veces. La he rehecho desde el principio también varias veces y no sé qué puede pasar.

El Mikrotik de Pepe2 en principio estará como switch para los puertos 1-3 y el 4 para el túnel, aunque eso ahora es lo de menos. Lo principal es levantar el WG.

Os dejo por aquí la config de ambos equipos (la de Pepe1 no, que esa funciona) a ver si se os ocurre algo...

Paco:
Código:
# sep/10/2022 18:55:04 by RouterOS 7.5
# software id = NU3D-YQYI
#
# model = RB750Gr3
# serial number = CC210F783B65
/interface bridge
add comment="Bridge Red Local" igmp-snooping=yes name=bridge-iptv
/interface eoip
add local-address=172.17.0.2 mac-address=FE:57:40:DF:13:95 mtu=1500 name=\
    eoip-iptv-Pepe1 remote-address=172.17.0.1 tunnel-id=0
add local-address=172.17.0.6 mac-address=02:2B:12:8C:4B:EA mtu=1500 name=\
    eoip-iptv-Pepe2 remote-address=172.17.0.5 tunnel-id=1
/interface wireguard
add listen-port=21008 mtu=1420 name=wg-sts-iptv-Pepe1
add listen-port=13231 mtu=1420 name=wg-sts-iptv-Pepe2
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/port
set 0 name=serial0
/interface bridge port
add bridge=bridge-iptv interface=ether5
add bridge=bridge-iptv interface=ether1
add bridge=bridge-iptv interface=eoip-iptv-Pepe1
add bridge=bridge-iptv interface=ether2
add bridge=bridge-iptv interface=ether3
add bridge=bridge-iptv interface=ether4
add bridge=bridge-iptv interface=eoip-iptv-Pepe2
/interface wireguard peers
add allowed-address=0.0.0.0/0 endpoint-address=e7e60e421cae.sn.mynetname.net \
    endpoint-port=54321 interface=wg-sts-iptv-Pepe1 persistent-keepalive=25s \
    public-key="W88x//TIAYPOXPmk4yUDRyDFAZA6wV9ZTpfUHGj5L0w="
add allowed-address=0.0.0.0/0 endpoint-address=8b0d087264c5.sn.mynetname.net \
    endpoint-port=54321 interface=wg-sts-iptv-Pepe2 persistent-keepalive=25s \
    public-key="LNzunTCWhg/XrMAKOW03I3ks2P/ZvEzZsO4p6MGyYQw="
/ip address
add address=172.17.0.2/30 interface=wg-sts-iptv-Pepe1 network=172.17.0.0
add address=172.17.0.6/30 interface=wg-sts-iptv-Pepe2 network=172.17.0.4
/ip cloud
set ddns-enabled=yes
/ip dhcp-client
add interface=bridge-iptv
/ip dns
set servers=1.1.1.1,1.0.0.1
/ip route
add disabled=no distance=1 dst-address=172.16.0.0/24 gateway=172.17.0.1 \
    pref-src="" routing-table=main scope=30 suppress-hw-offload=no \
    target-scope=10
add disabled=no distance=1 dst-address=192.168.10.0/24 gateway=172.17.0.5 \
    pref-src=0.0.0.0 routing-table=main scope=30 suppress-hw-offload=no \
    target-scope=10
/system clock
set time-zone-name=Europe/Madrid
/system identity
set name=Paco

Y aquí Pepe2
Código:
# sep/10/2022 19:03:32 by RouterOS 7.5
# software id = TFTJ-YQGJ
#
# model = RouterBOARD 941-2nD
# serial number = 8B0D087264C5
/interface bridge
add igmp-snooping=yes name=bridge-iptv
add name=bridge-local
/interface wireless
set [ find default-name=wlan1 ] ssid=MikroTik
/interface eoip
add local-address=172.17.0.5 mac-address=02:10:5B:8F:DC:35 mtu=1500 name=\
    eoip-iptv-Pepe2 remote-address=172.17.0.6 tunnel-id=1
/interface wireguard
add listen-port=54321 mtu=1420 name=wg-sts-iptv-Pepe2
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/interface bridge port
add bridge=bridge-local interface=ether1
add bridge=bridge-local interface=ether2
add bridge=bridge-local interface=ether3
add bridge=bridge-iptv interface=ether4
/interface wireguard peers
add allowed-address=172.17.0.6/32 interface=wg-sts-iptv-Pepe2 public-key=\
    "s5wjuY1zJmwJ3c1tWLYDfzLiSKSeIm/Ykz/MUToiBiU="
/ip address
add address=192.168.10.5/24 interface=bridge-local network=192.168.10.0
add address=172.17.0.5/30 interface=wg-sts-iptv-Pepe2 network=172.17.0.4
/ip cloud
set ddns-enabled=yes
/ip dns
set servers=1.1.1.1,8.8.8.8
/system clock
set time-zone-name=Europe/Madrid
/system identity
set name=Pepe2

Como llevo muchas horas seguidas peleándome con esto creo que ya he entrado en un bucle y no sé ni dónde mirar. Si a alguien se le ocurre qué está pasando, todas las pruebas serán bienvenidas.

PD: La semana pasada, el router que ahora tiene Paco estaba en casa de Pepe2, también detrás del router de la operadora y levantaba perfectamente el túnel hacia Pepe1. Ayer se fue para la ubicación del diagrama y ha aparecido Pepe2 en escena, con su correspondiente nuevo túnel (o intento de).
 
Última edición:
Cómo sabes que el túnel no está levantando, ¿cómo lo pruebas? ¿llegaste a hacer un ping a las 172.17.x.y? Lo que te falta en esa configuración es meter el EoIP en el bridge iptv en el Pepe2.

De cualquier forma, yo usaría esa ese equipo como router, montando la config de los túneles sobre la config original, no con la configuración que tienes.

Saludos!
 
Hola @pokoyo, siempre al rescate jeje

Cómo sabes que el túnel no está levantando, ¿cómo lo pruebas? ¿llegaste a hacer un ping a las 172.17.x.y?
Sí, comprobé los túneles por ping.

Desde Paco llego Pepe1 tirando un ping a la 172.17.0.1 y desde Pepe1 a Paco tirando el ping a la 172.17.0.2. Todo ok. Y conectándome en el puerto asignado en el RB3011 compruebo que efectivamente estoy en la red de Paco.

Desde Paco a Pepe2, la 172.17.0.5 no responde y desde Pepe2 a Paco, la 172.17.0.6 tampoco.

Además, nunca se ha llegado a hacer el handshake entre Paco y Pepe2
1662848065040.png


Y el Tunel EoIP tampoco está funcionando:
1662848260658.png




Lo que te falta en esa configuración es meter el EoIP en el bridge iptv en el Pepe2.
Sí, tienes razón. El último export fue ya tras un nuevo reset del router y vuelta a empezar. Me olvidé de meterlo antes de exportar. De todas formas ahora que lo he hecho tampoco arregla nada.


De cualquier forma, yo usaría esa ese equipo como router, montando la config de los túneles sobre la config original, no con la configuración que tienes.
Pregunta tonta... ¿Qué ganaría poniéndolo como router en vez de como switch? Quiero decir: Lo había pensado poner como switch porque los 4 puertos del router de la operadora de Pepe2 están ocupados. Necesito liberar uno para conectar el Mikrotik y ese cable que desconecto lo conecto después al Mikrotik, de ahí que me interesase que siguiese todo en la misma red. Con dos puertos ya ocupados, me queda otro para asignar al hipotético deco y el cuarto libre, por si necesitase conectar algún otro dispositivo en la red propia de Paco2. Si lo pongo como router, entiendo que el cable que desconecte del router del ISP y lo conecte al Mikrotik va a estar en otra red distinta y por lo tanto no visible desde otros dispositivos del hogar. Pero como todo esto ahora mismo es un escenario de pruebas, la verdad que me da igual router que switch si dices que es mejor router.



:!: Edito: La madre que me parió... Pepe2 estaba sin salida a internet. Acabo de añadir la siguiente ruta y al momento ha levantado todo :rolleyes::rolleyes::rolleyes: Qué vergüenza.No borro el mensaje por si le sirve a alguien que esté en la misma situación que sino eliminaba todo sin dejar rastro, vamos.
1662849689821.png


1662849733574.png


1662849710930.png
 

Adjuntos

  • 1662848126975.png
    1662848126975.png
    8.8 KB · Visitas: 33
  • 1662849625400.png
    1662849625400.png
    24 KB · Visitas: 42
Última edición:
Arriba