MANUAL: Mikrotik, manejo de APs usando CAPsMAN

Introducción
Hoy quiero presentaros una herramienta muy chula que tienen los routers mikrotik. Es una herramienta que quizá no uséis nunca, pero que si la necesitáis, está bien que sepáis que está ahí y para qué se usa. Hablo de CAPsMAN, el controlador centralizado para manejar configuraciones inalámbricas remotas. La idea de CAPsMAN es bien sencilla: un único lugar donde demos de alta reglas de provisionamiento, las cuales recogerán APs (puntos de acceso inalámbricos) remotos. De esta manera, si tenemos que realizar un despliegue grande, lo único que tendremos que hacer es configurar una vez CAPsMAN, y repartir los APs allá donde los necesitemos. Si necesitamos realizar un cambio en la parte inalámbrica de uno de los equipos AP, no tendremos que ir a donde esté ese equipo, desconectarlo, llevarlo donde tengamos nuestro centro de mandos y reconfigurarlo. Simplemente aplicaremos una nueva configuración y esta llega a todos los APs conectados al manger.

Propósito
En realidad, ninguno. Me propuse aprender esto porque me parecía una idea muy interesante, pero es verdad que es algo que vais a usar poco o nada a nivel doméstico, donde tendrás un par de APs y listo. No obstante, como el saber no ocupa lugar, me propuse entender cómo funcionaba y qué se podía hacer con él. Ahora mismo lo uso para controlar un segundo router, un pequeño mAP-lite que tengo conectado a una de las bocas de mi hex-s para montar la red de invitados. Sin embargo, como estos routers son bien agradecidos a la hora de jugar con ellos, me valió para aprender a centralizar la configuración en un único lugar y ahora creo que no volvería a tener nunca los APs fuera de CAPsMAN. Me resulta muy cómodo meterme en un único equipo y desde ahí realizar cualquier cambio, tanto en el propio equipo, como en el CAP. Además, si tenéis un router inalámbrico como CAPsMAN, su parte wifi también la podréis controlar de manera centralizada (se me ocurre el caso de un router wifi como router principal y un par de APs más repartidos por casa).

La teoría: ¿Qué es CAPsMAN?
CAPsMAN es una aplicación dentro de los routers mikrotik, para el manejo centralizado de múltiples puntos de acceso inalámbricos, también llamados CAPs. Es una manera fácil y sencilla de centralizar la configuración de varios dispositivos en un único lugar, de tal manera que se aplique y actualice simultáneamente en todos a la vez. Incluso, como he comentado ya, la propia interfaz inalámbrica de un router que haga de CAPsMAN, puede ponerse a trabajar en modo CAP, recibiendo la configuración del manager.

CAPsMAN es capaz de manejar cualquier interfaz inalámbrica (2,4 o 5GHz) de un equipo mikrotik. Como es una herramienta propietaria dentro del software de mikrotik, de momento, es sólo compatible con sus equipos. En la herramienta podremos definir distintas configuraciones que enviar a distintos puntos de acceso, filtrando por su dirección MAC, las cuales desplegarán las distintas redes inalámbricas de manera dinámica. Además, podremos crear reglas de acceso, controlar los rates del AP, e incluso generar certificados de emparejamiento entre el router que hace de manager y los distintos CAPs, tal que nadie pueda venir y plantar un AP en modo CAP si no está previamente autorizado a ello.

Los CAP, tienen básicamente tres formas de trabajar. La primera y más habitual, es reenviar todo el tráfico al manager, y que él se encargue de gestionarlo. Es la manera más usada, y la que se describe en este manual. Otra manera muy interesante es poder manejar un CAP de manera remota, sin que el equipo esté conectado físicamente a tu mananger (CAPsMAN en una ubicación, y CAP en otra distinta remota), vía conexión vpn, enviando al manager remoto el tráfico que se genera en el CAP, a través de internet. La tercera es el modo local forwarding, donde tenemos un caso parecido al anterior (manager y CAP en ubicaciones distintas), pero en este caso lo único que vamos a propagar por la VPN serán las configuraciones: el tráfico que genere el CAP se queda en el propio CAP, aprovechando la conexión a internet en la localización donde esté desplegado, y dejando el túnel VPN abierto simplemente para su administración remota.

Manos a la obra
Todo el proceso se realizará vía webfig/winbox, si bien adjunto los comandos correspondientes para el alta de los distintos elementos de configuración de CAPsMAN. Para este ejemplo, configuraremos un único AP con dos redes inalámbricas distintas: nuestra red principal y la red de invitados. Como router principal, usaré mi propio equipo habitual, un hex-s, y como CAP, el mAP-lite. La configuración es aplicable a cualquier equipo inalámbrico de la marca, si bien tendréis que crear distintas cofiguraciones para las distintas interfaces inalámbricas que tenga el equipo, para equipos de doble banda.

Para esta configuración partimos de un router de sólo cable ya configurado, con los siguientes datos:
Modo de trabajo: router​
Segmento de red LAN: 192.168.88.0/24 (el que trae por defecto)​
Bridge principal: todos los puestos salvo el puerto que hace de WAN. En mi equipo, puertos del 2 al 5. Asumimos nombre del bridge princpal: bridge-lan​
Servidor DHCP: trabajando y entregando direcciones en la red 192.168.88.0/24, con 192.168.88.1 como gateway principal​

Con dicha configuración, paso a detallar los pasos para dar de alta una red de invitados independiente de la red principal, y propagar la configuración de ambas redes de manera inalámbrica usando CAPsMAN.

Como primer paso, prepararemos el router principal, dando de alta un nuevo bridge donde recogeremos el tráfico que venga del CAP. A ese nuevo bridge le asigneremos un segmento de red distinto, que luego nos permitirá montar reglas de firewall para impedir que ambas redes se vean entre ellas. Aparte de lo anterior, daremos de alta un servidor dhcp encargado de entregar las direcciones a los clientes que se conecten al CAP
Código:
##########################################################################
################ Configuracion inicial del router ########################
##########################################################################
# Configuramos inicialmente el router maestro, nuestro CAPsMAN,
# para soportar una nueva red inalámbrica de invitados
# como queremos separar la red de invitados de la personal,
# creamos un nuevo bridge y una nuevo rango de red para él.
# Suponemos que existe un bridge principal llamado "bridge-lan"
# donde está funcionado la red principal, en el segmento 192.168.88.0/24
##########################################################################

# Damos de alta el nuevo bridge
/interface bridge
add name=bridge-guests

# Damos de alta un nuevo rango de IPs para ese bridge
/ip address
add address=192.168.99.1/24 interface=bridge-guests network=192.168.99.0

# Creamos un nuevo servidor DHCP para ese rango de IPs
# Primero, el rango
/ip pool
add name=pool-guests ranges=192.168.99.2-192.168.99.254

# Luego damos de alta la nueva red para el servidor DHCP
/ip dhcp-server network
add address=192.168.99.0/24 gateway=192.168.99.1

# Y levanteamos el servidor DHCP
/ip dhcp-server
add address-pool=pool-guests disabled=no interface=bridge-guests name=dhcp-guests

# Por último, configuraremos el firewall para impedir el acceso
# de los clientes de la red de invitados a nuestra red principal y viceversa
/ip firewall filter
add action=drop chain=forward comment="block guests accesing LAN" \
src-address=192.168.99.0/24 dst-address=192.168.88.0/24
add action=drop chain=forward comment="block LAN accesing guests" \
src-address=192.168.88.0/24 dst-address=192.168.99.0/24

Una vez listo el router principal, añadimos las configuraciones de CAPsMAN. Básicamente, se resumen en:
  • Dar de alta la tasa de transferencia mínima (rates) que va a anunciar el AP (opcional)
  • Dar de alta la seguridad que usará nuestra configuracion/es de wifi
  • Dar de alta los canales que usarán los CAPs (opcional, aunque muy recomendable en 2,4GHz)
  • Definir dónde va a parar el tráfico que se genere en el CAP
  • Dar de alta las configuraciones para las disntintas redes, basadas en lo que ya hemos definido antes
  • Crear la regla o reglas de provisionamiento para los distintos APs
Código:
##########################################################################
################################# CAPsMAN ################################
##########################################################################
# Definimos una tasa se transferencia mínima
# Asi nos aseguramos de que el AP no anuncia velocidades inferiores a g/n
/caps-man rates
add basic=24Mbps name=g/n-only supported=24Mbps,36Mbps,48Mbps,54Mbps

# Definimos nuestra contraseña para la red inalámbrica de invitados,
# y otra para nuestra red principal. Obviamente, definidla según vuestro criterio
/caps-man security
add authentication-types=wpa2-psk encryption=aes-ccm group-encryption=aes-ccm \
    name=security-profile-guests passphrase=b13nb3n1d0s
add authentication-types=wpa2-psk encryption=aes-ccm group-encryption=aes-ccm \
    name=security-profile-lan passphrase=My.SuperW1f1S3cr2t!

# Definimos dónde irá a parar el tráfico del AP
# El tráfico de la red wifi interna irá al bridge principal, bridge-lan
# mientras que el de la red de invitados irá al nuevo bridge-guests
# En la red de invitados, no permitimos la comunicación entre clientes,
# así los invitados no se ven entre sí [client-to-client-forwarding=no]
# El tráfico que se genera en el AP se reenvía al router principal,
# pasando así por sus reglas de firewall [local-forwarding=no], para ambas redes
/caps-man datapath
add bridge=bridge-guests client-to-client-forwarding=no local-forwarding=no \
    name=datapath-guests
add bridge=bridge-lan client-to-client-forwarding=yes local-forwarding=no \
    name=datapath-lan

# Definimos los posibles canales [no es obligatorio]
# De estos, luego elegiremos uno para nuestra red,
# el que más nos convenga mirando la saturación del entorno inalámbrico
/caps-man channel
add band=2ghz-g/n control-channel-width=20mhz frequency=2412 name=channel1
add band=2ghz-g/n control-channel-width=20mhz frequency=2437 name=channel6
add band=2ghz-g/n control-channel-width=20mhz frequency=2462 name=channel11

# Damos de alta una configuración a enviar a uno o varios APs.
# En ella seleccionamos el canal de la wifi, el país,
# en qué datapath va el tráfico, el nombre de la red y su seguridad
# Como tenemos dos redes, damos de alta dos configuraciones,
# una para nuestra lan interna, y otra para invitados.
# Como estamos usando un AP con un único "radio", debemos seleccionar
# el mismo canal para ambas configuraciones
/caps-man configuration
add channel=channel1 country=spain datapath=datapath-guests mode=ap name=\
    wifi-guests rates=g/n-only security=security-profile-guests ssid=guests
add channel=channel1 country=spain datapath=datapath-lan mode=ap name=\
    wifi-lan rates=g/n-only security=security-profile-lan ssid=MySuperWiFiName

# Creamos una regla de provisión dinámica, sin filtrar por MAC
# Todo AP en modo CAP pinchado a la interfaz que definamos como CAPsMAN,
# obtendrá esta configuración dinámicamente
# Como configuración principal irá la de nuestra red privada, y como configuración
# esclave irá la de la red de invitados (2 APs virtuales, con un único radio)
/caps-man provisioning
add action=create-dynamic-enabled master-configuration=wifi-lan \
    slave-configuration=wifi-guests name-format=identity

# Definimos qué interfaz nos comunica con los APs.
# Aquí podría ir una interfaz física concreta (etherX) o un bridge.
# Supongo que el AP está conectado al router principal en un puerto
# que forma parte del bridge principal de la red local, "bridge-lan"
/caps-man manager interface
set [ find default=yes ] forbid=yes
add disabled=no interface=bridge-lan

# Y por último, habilitamos CAPsMAN
/caps-man manager
set enabled=yes

Una vez hecho esto, hemos terminado con el manager. En las tres pestañas más a la derecha de CAPsMAN, podremos ver los disntios CAP filiados al manager, los radios que controla para cada uno de los CAP (en mi caso sólo uno porque no tengo equipos doble banda), y en la última pestaña los clientes conectados a cada CAP. Las pestañas son, por órden, Remote CAP, Radio y Registration Table, respectivamente

Ahora sólo nos hace falta poner los equipos esclavos en modo CAP y conectarlos usando la interfaz que definamos para buscar el manager. En mi caso, es tan sencillo que hasta se puede hacer desde el quick setup de ese equipo:
1599056219134.png


Los comandos para hacerlo vía consola son los siguientes:

Código:
##########################################################################
################### Configuración del CAP [el AP] ########################
##########################################################################

# Añadimos el nombre del equipo
/system identity
set name=remote-cap

# Metemos todos los puertos en el bridge,
# tanto puertos ethernet físicos como wlan
# En el caso de este equipo, sólo estos dos
# porque únicamente tiene un puerto ethernet
/interface bridge port
add bridge=bridge comment=defconf interface=ether1
add bridge=bridge interface=wlan1

# Levantamos un cliente DHCP sobre el bridge,
# para que el router esté accesible por IP desde el CAPsMAN
/ip dhcp-client
add comment=defconf disabled=no interface=bridge

# Indicamos que este equipo es un CAP, controlado vía CAPsMAN
# Indicamos cual es su bridge principal, por dónde va a descubir
# al manager (el mismo bridge en este caso) y qué interfaz o interfaces
# inlámbricas van a ser controladas vía CAPsMAN
/interface wireless cap
set bridge=bridge discovery-interfaces=bridge enabled=yes interfaces=wlan

#############################################################################################
########################### IMPORTANTE CAP = CPAsMAN Ej: hAP-ac3 ############################
#############################################################################################
# Si nuestro router es al mismo tiempo CAPsMAN y quieremos controlas sus interfaces
# inalámbricas como CAP, la configuración del CAP es ligeramente disitnta. En este caso no
# necesitamos un discover interface, sino apuntar a localhost para descubrir CAPsMAN
# En este ejemplo controlamos dos interfaces wlan1 y wlan2 como cap, desde un CAPsMAN
#############################################################################################
/interface wireless cap
set bridge=bridge caps-man-addresses=127.0.0.1 enabled=yes interfaces=wlan1,wlan2

Si todo ha ido bien, veremos nuestros APs remotos en la primera pestaña del manager, creados de manera dinámica, como se muestra a continuación:

1599056433352.png



Y listo, ya tenemos funcionando nuestros APs usando CAPsMAN. Espero os sirva de ayuda y tengáis en consideración esta herramienta. Tanto si el despliegue es grande como chico, la posibilidad de centralizar su configuración es siempre de gran ayuda.

Saludos!
 
Última edición:
Muchas gracias por tus manuales.
Tenemos lectura y entretenimiento para rato.
Al final Mikrotik te tendrá que encargar la Wiki en español. ;)
Un lujo para los usuarios de esta marca.
Saludos.
 
Muchas gracias por tus manuales.
Tenemos lectura y entretenimiento para rato.
Al final Mikrotik te tendrá que encargar la Wiki en español. ;)
Un lujo para los usuarios de esta marca.
Saludos.
Me alegro de que te gusten. Y, sobre todo, de que os sean de ayuda.

Saludos!
 
Estoy esperando un Audience... y buscando un segundo... he leido que el proprio Audience hace de CAPs server, pero me queda la duda... donde deberia hacerlo... en el router core o en el proprio audience?
 
Estoy esperando un Audience... y buscando un segundo... he leido que el proprio Audience hace de CAPs server, pero me queda la duda... donde deberia hacerlo... en el router core o en el proprio audience?

Lo puedes hacer en el equipo que quieras. Y, si el propio equipo que hace de CAPsMAN tiene interfaz/es inalámbricas, esta/s también se pueden controlar desde el propio CAPsMAN (es decir, que un equipo haga de CAPsMAN y de CAP, al mismo tiempo).

No obstante yo probaría primero los audience por separado, especialmente si vas a querer usar sus capacidades de wifi mesh, que no se qué tal se van a llevar con el tema de CAPsMAN (no he tenido nunca esos equipos, así que no lo he probado).

La principal diferencia entre un audience y cualquier otro equipo es que no tienes dos radios (wifi N y wifi AC) sino tres. Ese tercer radio se usa para montar la red mesh y comunicar entre sí los distintos routers audience, mientras que los otros dos son los que quedan siponibles para tu uso (tu AP doble banda, de toda la vida). Estas dos supongo que sí se podrían meter vía CAPsMAN, como en cualquier otro equipo.

En definitiva, prueba y saca tus propias conclusiones.

Saludos!
 
Mi idea era de gestionar todo desde el CORE... y que el CORE gestionara solito el MESH... Añadir un tercero AP en el futuro, algo tan sencillo como añadirlo a la granja... por lo menos las demás marcas van de este modo.
 
Mi idea era de gestionar todo desde el CORE... y que el CORE gestionara solito el MESH... Añadir un tercero AP en el futuro, algo tan sencillo como añadirlo a la granja... por lo menos las demás marcas van de este modo.

Sí, sospecho que esta también. Lo que no tengo tan claro es cómo se gestiona el wifi cuando unes mesh y CAPsMAN, porque los audience, al mismo tiempo, llevan también un configuración del palo "tocar un botón y listo" y eso es porque uno de los routers está haciendo una función similar a la que realiza CAPsMAN, centralizando la configuración del wifi en un único equipo.

Lo que te digo es que, como no los he tenido aún a mi alcance, no sé si esos equipos se pueden meter bajo CAPsMAN y que el CORE, como tú lo llamas, maneje todos los AP's, pertenezcan o no a una red mesh. A eso me refiero.

Pero vamos, que es cuestión de probar y listo.

Saludos!
 
Buenos dias.
Estoy empezando a leer el manual para CAPsMAN y quisiera preguntaros una duda que tengo.
Cual es la mejor opcion de configuración del hap mini para después utilizarlo en la red de capsman pero pensando que tambien me gustaría que lleve internet por cable a una tele que estara a su laso en la cocina ( la ref llega a traves de conector PLC)
Gracias y saludos
 
Reset y configuración como CAPs mode. Esto aplica la siguiente configuración:
  • Mete todos los puertos en el mismo bridge, haciendo que el equipo se comporte como un switch.
  • Levanta un cliente DHCP sobre dicho bridge, obteniendo una IP para administración, del router principal.
  • Pone las interfaces inalámbricas en modo CAP, para escuchar la configuración de un CAPsMAN.

Vamos, que lo deja justo para lo que quieres hacer. Te quedaría reservarle en el lease la IP que quieras a la MAC que monte como administración en el bridge, y listo.

Para CAPsMAN, no te compliques, usa como base el fichero adjunto, que ya hemos ido montando con otro compañeros. Luego afinaremos y, si quieres creamos una regla de provisioning específica para cada AP. Pero, de entrada, te vale así.

En esta configuración la red de 2,4GHz emite a 17dBm, es decir, a unos 50mW, en lugar de los 20dBm, 100mW, que emite por defecto. Si ves que se queda "coja" simplemente, le quitas ese valor en la definición de los canales, y le dejas que coja el tope, que son los 20dBm en 2,4GHz. Esto está hecho así para primar la red de 5GHz por encima de la otra.

Antes de importar el fichero, cambia la password de la wifi por defecto que he llamado "albter" y el propio nombre de la wifi. La password va difinida en los security profiles (/caps-man security) y el SSID de las redes en la configuración (/caps-man configuration).

Una vez hechos tus cambios, sube ese fichero al router principal y lo importas. Reseteas el hAP mini desde System -> Reset configuration, y le marcas la opción de "CAPs MODE". Según lo conectes por uno de sus puertos ethernet al router principal (bien sea directo o mediante el PLC), tendrás lo que buscas.

Cuando lo tengas, me avisas, y te digo cómo configurar tu router principal para poner sus interfaces inalámbricas bajo CAPsMAN.

Saludos!
 

Adjuntos

  • albter.zip
    8.2 KB · Visitas: 52
Reset y configuración como CAPs mode. Esto aplica la siguiente configuración:
  • Mete todos los puertos en el mismo bridge, haciendo que el equipo se comporte como un switch.
  • Levanta un cliente DHCP sobre dicho bridge, obteniendo una IP para administración, del router principal.
  • Pone las interfaces inalámbricas en modo CAP, para escuchar la configuración de un CAPsMAN.

Vamos, que lo deja justo para lo que quieres hacer. Te quedaría reservarle en el lease la IP que quieras a la MAC que monte como administración en el bridge, y listo.

Para CAPsMAN, no te compliques, usa como base el fichero adjunto, que ya hemos ido montando con otro compañeros. Luego afinaremos y, si quieres creamos una regla de provisioning específica para cada AP. Pero, de entrada, te vale así.

En esta configuración la red de 2,4GHz emite a 17dBm, es decir, a unos 50mW, en lugar de los 20dBm, 100mW, que emite por defecto. Si ves que se queda "coja" simplemente, le quitas ese valor en la definición de los canales, y le dejas que coja el tope, que son los 20dBm en 2,4GHz. Esto está hecho así para primar la red de 5GHz por encima de la otra.

Antes de importar el fichero, cambia la password de la wifi por defecto que he llamado "albter" y el propio nombre de la wifi. La password va difinida en los security profiles (/caps-man security) y el SSID de las redes en la configuración (/caps-man configuration).

Una vez hechos tus cambios, sube ese fichero al router principal y lo importas. Reseteas el hAP mini desde System -> Reset configuration, y le marcas la opción de "CAPs MODE". Según lo conectes por uno de sus puertos ethernet al router principal (bien sea directo o mediante el PLC), tendrás lo que buscas.

Cuando lo tengas, me avisas, y te digo cómo configurar tu router principal para poner sus interfaces inalámbricas bajo CAPsMAN.

Saludos!
ya lo tengo todo...creo :ROFLMAO:
 
Y, lo más in portante, ¿funciona? Si lo has hecho bien, el hAP mini debería estar emitiendo dos WiFis, y tener sendas interfaces cAP en la primera pestaña de CAPsMAN.

Así mismo, el equipo conectado al hAP mini por cable, debería obtener IP del router principal.

Saludos!
 
Y, lo más in portante, ¿funciona? Si lo has hecho bien, el hAP mini debería estar emitiendo dos WiFis, y tener sendas interfaces cAP en la primera pestaña de CAPsMAN.

Así mismo, el equipo conectado al hAP mini por cable, debería obtener IP del router principal.

Saludos!
la wifi no me sale en el ap mini....la television conectada detras de el tiene ip del cap ac3
en la primera pestaña del capsman no sale nada y en interface list sale esto.
edito para comentarte que tiene en mismo nombre la red wifi del ac3 y la del mini.
 

Adjuntos

  • captura_2.png
    captura_2.png
    98 KB · Visitas: 61
Dame un export ambos equiops y pega el mismo pantallazo al hAP ac3 en la lista de interfaces y en CAPsMAN. Cada vez que hable de CAPsMAN = hAP ac3. Es decir, donde hay que subir la configuración que te he dado es en el hAP ac3, que es quien comanda CAPsMAN.

Saludos!
 
Dame un export ambos equiops y pega el mismo pantallazo al hAP ac3 en la lista de interfaces y en CAPsMAN. Cada vez que hable de CAPsMAN = hAP ac3. Es decir, donde hay que subir la configuración que te he dado es en el hAP ac3, que es quien comanda CAPsMAN.

Saludos!
Después te lo paso que me ha salido “trabajo”
Yo el albter.zip lo he introducido en el mini .....
Entonces lo pongo en el ac3 ??
Hasta luego
 
Claro compi. El CAPsMAN es el equipo principal, el que comanda. El otro es un mero AP tonto que escucha lo que le dicen. Mete el .rsc en el router hAP ac3, el que va a hacer de principal, y resetea el otro de nuevo, usando la misma opción de CAPs Mode

Saludos!
 
Claro compi. El CAPsMAN es el equipo principal, el que comanda. El otro es un mero AP tonto que escucha lo que le dicen. Mete el .rsc en el router hAP ac3, el que va a hacer de principal, y resetea el otro de nuevo, usando la misma opción de CAPs Mode

Saludos!
Es que soy muy corto ;)
Gracias por la paciencia
Después me pongo
 
Dame un export ambos equiops y pega el mismo pantallazo al hAP ac3 en la lista de interfaces y en CAPsMAN. Cada vez que hable de CAPsMAN = hAP ac3. Es decir, donde hay que subir la configuración que te he dado es en el hAP ac3, que es quien comanda CAPsMAN.

Saludos!
aqui te los dejo
saludos
 

Adjuntos

  • albter_ac3.txt
    4.9 KB · Visitas: 47
  • albter_mini.txt
    845 bytes · Visitas: 35
  • capsman_ac3.png
    capsman_ac3.png
    103.4 KB · Visitas: 62
  • interface_ac3.png
    interface_ac3.png
    105.3 KB · Visitas: 60
Vale, ahora sube el fichero .rsc al hAP ac3, y corre el comando desde terminal para importarlo:
Código:
import capsman-v2.rsc

Y eso aplicará dicha configuración sobre el hAP ac3.

Saludos!
 
Vale, ahora sube el fichero .rsc al hAP ac3, y corre el comando desde terminal para importarlo:
Código:
import capsman-v2.rsc

Y eso aplicará dicha configuración sobre el hAP ac3.

Saludos!
echo.
ahora si que salen las dos interfaces en capsman
 
Pues listo, eso quiere decir que CAPsMAN funciona. Ahora puedes probar a conectarte a ambas redes. Tu red privada debe de tener acceso al resto de los equipos de la red, mientras que la red de invitados, al no tener default forward, no debería ver al resto de los equipos de red conectados a esa misma wifi.

Una vez comprobado eso, lo único que te queda hacer en el hAP ac3 es poner sus interfaces inalámbricas a disposición de CAPsMAN. Para ello, simplemente vas a la pestaña Wireless y reseteas la configuración inalámbrica de cada una de las dos interfaces (ojo haz este paso por cable, para no quedarte fuera de la red) el botón del reset de la interfaz inalámbrica lo tienes dentro de cada interfaz física. Una vez reseteado, en la pantalla principal donde se listan las interfaces inalámbricas, tendrás un botón que pone “CAP” y simplemente pulsas en él para activar el modo cap de ese equipo. Como interfaces a controlar le pasas ambas (es una lista, añades tanto wlan1 como wlan2) y en el campo CAPsMAN address pones la IP 127.0.0.1. Una vez hecho, en la pestaña Wireless aparecerán unas líneas en rojo indicando que esas dos interfaces ahora se manejan vía CAPsMAN y, si todo ha ido bien, tendrás no dos, sino cinco interfaces nuevas en la pestaña “CAP Interface” de CAPsMAN. Las dos que tenías del hAP mini, más las dos nuevas (normal e invitados) para la red de 2,4GHz del hAP ac3, más la red normal de 5HGz en este último equipo.

Prueba y me dices.

Saludos!
 
Arriba