MANUAL: Mikrotik, configuraciones básicas ISPs

Buenos días @pocoyo y @furny,

Muchas gracias por responder, fuí copiando y pegando cada una de las líneas, desde notepad hasta el terminal de winbox, siguiendo el orden de las líneas del código y procurando no copiar espacios ni saltos de línea. De hecho no me dió ningún error hasta que llegué a esas líneas que comentaba.

@pocoyo, si no es mucho jaleo ni molestia para tí, te lo agradecería. Si no, informadme por favor cómo debería cargar vía terminal el paquete multicast como indica @furny, con eso creo que me bastaría. Una vez consiga introducir todo el código completo y sin errores, y compruebe que todo funciona correctamente, exportaría la configuración a *.rsc por si le es de utilidad a algún/a compañero/a.

Como siempre, muchas gracias a ambos por vuestra ayuda y rapidez en contestar.

Saludos.-

Tiene razón el compi @furny, tu problema probablemente no sea que los comandos tengan caracteres raros o espacios o tabuladores, sino que no tengas el paquete multicast instalado. Mira lo que me pasa a mi según empiezo a escribir el submenú de igmp-proxy, dentro de routing:

1601711930482.png


¿te suena, verdad? Yo tampoco tengo ese paquete instalado, razón por la que no tengo ese submenú "igmp-proxy" dentro de la opción de routing.

Para instalarlo, sólo tienes que localizar la arquitectura de tu router. Lo tienes en system -> resource

1601712243325.png


Una vez hecho, te vas a la web de mikrotik y localizas el "extra packages" para la versión estable (segunda columna) de tu arquitectura. En mi caso, sería este:

1601712423644.png


Te bajas el zip, lo descomprimes y verás que, en lugar de un meta-paquete, tienes cada paquete por separado. Ahí ya decides tú si sustituyes tu instalación actual por los paquetes que te interesen (no los subas todos, no hace falta), o si simplemente añades el de multicast.

1601712967048.png


Para la segunda opción, localizas el paquete de multicast y lo subes a la carpeta files. Le das un reinicio al equipo, y te debería aparecer instalado en System -> Packages

Saludos!
 
Buenos días,

@pocoyo, efectivamente, ese era el problema. Por este orden, he hecho un reset de fábrica al equipo, he borrado la cofiguración por defecto y he instalado el paquete multicast tal y como me has indicado.

Acto seguido, he copiado y pegado la configuración de @furny vía terminal, y esta vez no he recibido ningún mensaje de error.

Posteriormente, he incluído las líneas que @furny indicó para poder tener todos los servicios (IPTV+VOIP+Internet) en todas las bocas a excepción de la boca nº5. Copio lo que realicé:

"...con el Webfig o con Winbox entras en la pestaña de Bridge -> Ports. Pinchas en el botón "-" a la izquierda de
los puertos 3 y 4, con eso los quitas del bridge-LAN. Después en esa misma pestaña, arriba a la izquierda, pulsas
"add new", y añades al bridge-IPTV en "interface" el ether3 y deseleccionas HW Offloading. Después "apply" y
"ok". Después repites lo mismo para ether4..."

Tras instalarlo todo, decir que tengo internet y funciona correctamente, pero la parte de IPTV no va del todo bien. Aparece la guía de canales (muy lenta) pero no puedo navegar entre ella. Tampoco puedo acceder a contenido VOD (no aparece el menú...da mensaje de error de conexión), únicamente se visualiza el contenido en directo y debo cambiar de canal introduciendo el número de canal.

He probado a conectar el AP del que "cuelga" el deco, sobre otras bocas del MK, con mismo resultado.

Desconozco si he realizado mal algún paso...o falta algún tipo de configuración.

Como siempre, mil gracias por vuestra ayuda...., sin vosotros estaría perdido.

Saludos.-
 
Buenos días,

@pocoyo, efectivamente, ese era el problema. Por este orden, he hecho un reset de fábrica al equipo, he borrado la cofiguración por defecto y he instalado el paquete multicast tal y como me has indicado.

Acto seguido, he copiado y pegado la configuración de @furny vía terminal, y esta vez no he recibido ningún mensaje de error.

Posteriormente, he incluído las líneas que @furny indicó para poder tener todos los servicios (IPTV+VOIP+Internet) en todas las bocas a excepción de la boca nº5. Copio lo que realicé:

"...con el Webfig o con Winbox entras en la pestaña de Bridge -> Ports. Pinchas en el botón "-" a la izquierda de
los puertos 3 y 4, con eso los quitas del bridge-LAN. Después en esa misma pestaña, arriba a la izquierda, pulsas
"add new", y añades al bridge-IPTV en "interface" el ether3 y deseleccionas HW Offloading. Después "apply" y
"ok". Después repites lo mismo para ether4..."

Tras instalarlo todo, decir que tengo internet y funciona correctamente, pero la parte de IPTV no va del todo bien. Aparece la guía de canales (muy lenta) pero no puedo navegar entre ella. Tampoco puedo acceder a contenido VOD (no aparece el menú...da mensaje de error de conexión), únicamente se visualiza el contenido en directo y debo cambiar de canal introduciendo el número de canal.

He probado a conectar el AP del que "cuelga" el deco, sobre otras bocas del MK, con mismo resultado.

Desconozco si he realizado mal algún paso...o falta algún tipo de configuración.

Como siempre, mil gracias por vuestra ayuda...., sin vosotros estaría perdido.

Saludos.-

Cuando saque un rato montaré la configuración de @furny, pero partiendo de la configuración por defecto del quick set. Es decir, para resetear y empezar a meter líneas sobre la config que te deja el quick set, que sabemos es buena

La config de @furny es buena seguro, porque tiene pinta de un export de su propio equipo. Pero tal vez tu red es ligeramente distinta y de ahí venga el problema. Si quieres que lo revisemos, pásanos un export de cómo tienes ahora mismo la configuración de tus equipos y lo revisamos.

Ánimo, que ya casi lo tienes.

Saludos!
 
Si quieres que lo revisemos, pásanos un export de cómo tienes ahora mismo la configuración de tus equipos y lo revisamos.
eso. Sube un export y lo vemos cuando tengamos un rato. Recuérdanos también como tienes conectados finalmente los equipos, por favor.

Suerte!!
 
Tras instalarlo todo, decir que tengo internet y funciona correctamente, pero la parte de IPTV no va del todo bien. Aparece la guía de canales (muy lenta) pero no puedo navegar entre ella. Tampoco puedo acceder a contenido VOD (no aparece el menú...da mensaje de error de conexión), únicamente se visualiza el contenido en directo y debo cambiar de canal introduciendo el número de canal.
Otra cosa: debes tener los descos apagados antes de poner en marcha el router. Una vez este arranque, pones en on los descos. Tardan en cargar todo al principio, unos 5 minutos. Lo primero que se ven son los canales en directo. La guía tarda en cargarse eso, hasta 5m, depende de los servidores. Y el VOD igual, hasta que no ha cargado todo no va. Es cosa de Movistar. Cada vez que apagas un desco, tarda unos 5 minutos en funcionar a tope. Paciencia!!
 
Buenas tardes @pocoyo y @furny,

Adjunto archivo de configuración para que, cuando podáis, le echéis un vistazo. He omitido la IPTV address por seguridad (si la precisáis os la puedo remitir por privado).

En otro orden, he visto en la configuración de @furny que hace mención a una ONT de Alcatel, entiendo que es la configuración para poder acceder a la ONT a pesar de encontrarse en otro rango distinto al MK. En mi caso tengo una ONT Nokia que tiene la IP 192.168.100.1. ¿Se podría modificar la configuración?

Como no tengo posibilidad, de momento, de modificar la estructura de mi red, la configuración ha quedado tal cual estaba:

ONT -->Boca "Internet" del MK --> Bocas 2-3 del MK conectados SALÓN (AP Asus+Deco IPTV) y COCINA (AP Asus+Deco IPTV) / Boca 4 conectado ATA-SIP Grandstream / Boca 5 conectado DESPACHO (AP Asus+PC+NAS).

La Boca 5 ha quedado sólo con servicio Internet con HW Offloading, por lo que me viene perfecto para el PC del despacho y el NAS.

Si necesitáis cualquier otra información, a vuestra disposición.

Muchas gracias.


Saludos.-
 

Adjuntos

  • config.txt
    8.4 KB · Visitas: 19
Otra cosa: debes tener los descos apagados antes de poner en marcha el router. Una vez este arranque, pones en on los descos. Tardan en cargar todo al principio, unos 5 minutos. Lo primero que se ven son los canales en directo. La guía tarda en cargarse eso, hasta 5m, depende de los servidores. Y el VOD igual, hasta que no ha cargado todo no va. Es cosa de Movistar. Cada vez que apagas un desco, tarda unos 5 minutos en funcionar a tope. Paciencia!!

La verdad es que no había probado a desconectarlos de la red eléctrica y volverlos a conectar una vez el MK ha arrancado, los tenía en standby y los encendí cuando observé que el MK había arrancado y disponía de internet...no se si tiene algo que ver...

De lo que he podido observar en tu configuración, ¿los decos obtienen IP automática tal y como hacen con el HGU, es así?

Muchas gracias como siempre.


Saludos.-
 
La verdad es que no había probado a desconectarlos de la red eléctrica y volverlos a conectar una vez el MK ha arrancado, los tenía en standby y los encendí cuando observé que el MK había arrancado y disponía de internet...no se si tiene algo que ver...

De lo que he podido observar en tu configuración, ¿los decos obtienen IP automática tal y como hacen con el HGU, es así?

Muchas gracias como siempre.


Saludos.-
A ver. Vamos por partes.

1) Es importante que desenchufes los descos por completo de la red eléctrica. Es MUY importante, porque deben "olvidarse" de su antigua IP y tomar la nueva que les da el MK. O sea, los pones en off, los desenchufas de la red, vas poniendo en marcha el MK, y cuando este esté arriba (primero, al enchufarse el MK da un pitido, después, cuando ya está arriba y operativo, da dos pitidos), entonces, enchufas y pones en "on" los descos, para que pillen las nuevas direcciones de IP. Hay algunos descos que son un poco tozudos, y hay que volver a apagarlos y encenderlos (ya no hace falta apagar el MK). (Si con todo y con eso no la pillan, hay otro procedimiento, que si hace falta te lo diré). Puedes entrar en el MK y ver en /ip DHCP leases si los tres han pillado su respectiva dirección en el rango de su pool. Deja, como te decía antes, que pasen 5 minutos a que los descos cargen la guía, canales y tal.

En cuanto al VOD, en el MK el comportamiento, lamentablemente, no es perfecto, pues al RouterOS le falta el RTSP ALG (o helper). Para paliar esa falta, le metemos el famoso VOD script del compañero @toniros. Pero tiene sus "tics". Fíjate lo que publiqué yo sobre ese comportamiento hace un tiempo aquí #7,635.

Efectivamente, con esta nueva configuración los descos pillan las direcciones IP automáticamente. Lo hacen con esta regla que tienes metida:

/ip dhcp-server vendor-class-id
add address-pool=IPTV-desco-pool name="Movistar Desco" server=\
IPTV-dhcp-server vid="[IAL]"

2) He estudiado tu configuración y no he detectado grandes cosas, salvo lo siguiente:
2.a) El arranque del pppoe no sé si te lo está haciendo bien, pues te falta meter el "password" de telefónica=adslppp
2.b) No es esencila, pero si tu ONT NO es la Alcatel, es mejor que uses como mru y mtu=1492.
(Más adelante tienes este comentario:
# pppoe-out1 not ready
que no sé si es que has detectado que no te ha arrancado el pppoe, o qué, pero podrías tener problemas, si no)

La regla de arranque de internet (pppoe sobre vlan6) te debería quedar así:

/interface pppoe-client
add add-default-route=yes allow=pap,chap disabled=no interface=Internet-vlan6 \
keepalive-timeout=60 max-mru=1492 max-mtu=1492 name=pppoe-out1 password=\
adslppp use-peer-dns=yes user=adslppp@telefonicanetpa

3) Esto no es esencial, pero te sobra, pues si tienes un hEX RB750gr3, NO tienes wireless. Es más, fíjate en los paquetes que tienes instalados (/system packages), y si tienes habilitado el wireless, lo deshabilitas y haces un reboot (también, de paso, puedes deshabilitar ipv6, hotspot, mpls, pues no los va a usar). Y esta regla, la borras (se te irá al deshabilitar wireless).

/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik

4) No sé el acceso a la ONT de Nokia. Yo uso la Huawei, pero antes usaba la Alcatel. Si dices que para acceder a la Nokia debe estar en los rangos 192.168.100.0/24, pues reemplaza la regla por esta (no sé cuál es la dirección de acceso, en mi caso es por la 192.168.100.1, por eso para la interfaz e1 del router le puse una distinta, la .2):

/ip address
add address=192.168.100.2/32 comment="Router's address from ONT. Huawei's ONT \
HG8240H access through 192.168.100.1" interface=Gateway-e1 network=\
192.168.100.0

5) Es importante que hayas copiado no solo la dirección de tu red IPTV que te asigna Telefónica de tu HGU, sino también la netmask correcta. Has puesto la /9, pero fíjate que sea esa y no la /10 u otra.

/ip address
add address=10.159.xxx.xxx/9 comment="My Telefonica's IPTV address" \
interface=Iptv-vlan2 network=10.128.0.0

6) Esa regla me parece que se me olvidó meterla en la configuración que subí (no me hacía a mí falta, pues no tengo hosts colgando de mi subnet IPT-bridge, que no sean descos), o no la copiaste tú. Es necesaria para que puedas acceder desde los hosts colgando de la subred de IPTV a los hosts de la bridge-LAN (ponla antes de la de VOD Script, si ya estuviera creada; si no, ponla la última de las "masquerades"):

/ip firewall nat
add action=masquerade chain=srcnat comment="masq. IPTV subnet hosts" \
src-address=192.168.20.0/24

Con esto, y con paciencia con el VOD, te debería funcionar todo. Dímelo si no, y le damos otra vuelta.

Suerte!!!
 
Última edición:
Tenía una errata en la dirección de Gateway-e1, en la máscara. No es importante, pero... ya está corregida:

/ip address
add address=192.168.100.2/32 comment="Router's address from ONT. Huawei's ONT \
HG8240H access through 192.168.100.1" interface=Gateway-e1 network=\
192.168.100.0
 
Hola @furny !

te paso cómo quedarían los comandos a meter en un router reseteado con quick-set y crear la configuración IPTV multi-desco para Movistar.
Por favor, con paciencia y una cerveza de por medio, tranquilamente cuando puedas, le das un vistazo y si eres tan amable me confirmas que no he metido ninguna gamba. Si es así, lo subimos al primer comentario, como configuración multi-desco.
Código:
# Editamos el bridge principal para que sea
# compatible con Hardware Offloading
# para equipos con switch-chip MT7621
/interface bridge set bridge protocol-mode=none

# Sacamos ether2 del bridge principal
/interface bridge port remove numbers=[find interface=ether2]

# Creamos el nuevo bridge para IPTV
/interface bridge
add name=bridge-iptv igmp-snooping=yes

# Añadimos el puerto ether2 al nuevo bridge
/interface bridge port add bridge=bridge-iptv interface=ether2

# Añadimos las VLANs asociadas al puerto WAN
/interface vlan
add interface=ether1 name=internet-vlan6 vlan-id=6
add interface=ether1 name=iptv-vlan2 vlan-id=2
add interface=ether1 name=voip-vlan3 vlan-id=3

# Creamos el cliente PPPoE sobre la vlan6
/interface pppoe-client
add add-default-route=yes allow=pap,chap disabled=no interface=internet-vlan6 \
    keepalive-timeout=60 max-mru=1492 max-mtu=1492 name=pppoe-out1 password=\
    adslppp use-peer-dns=yes user=adslppp@telefonicanetpa

# Añadimos una nueva lista donde meteremos las vlans 2 y 3
/interface list
add comment="Vlan2 (Iptv) & Vlan3 (Voip)" name=Vlan2&3

# Metemos cada interfaz en su lista correspondiente
/interface list member
add interface=pppoe-out1 list=WAN
add interface=iptv-vlan2 list=Vlan2&3
add interface=voip-vlan3 list=Vlan2&3
add interface=bridge-iptv list=LAN

# Añadir la ip de IPTV, extraída de un backup del router
# Más info, aquí: https://alexariza.net/tutorial/como-obtener-los-datos-de-iptv-con-movistar/
# Sustituir el valor correspondiente en 10.XX.XX.XX/ZZ
/ip address
add address=10.XX.XX.XX/ZZ comment="My Telefonica's IPTV address, from NOLTARI" interface=\
    iptv-vlan2 network=10.128.0.0
add address=192.168.77.1/24 comment="IPTV subnet" interface=bridge-iptv network=\
    192.168.77.0

# Añadimos la opción especial para el dhcp del desco
/ip dhcp-server option
add code=240 name=option_para_deco value=\
    "':::::239.0.2.10:22222:v6.0:239.0.2.30:22222'"

# Añadimos un nuevo pool para los descos,
# y otro para el resto de los hosts en ese bridge-iptv
/ip pool
add name=pool-iptv-descos ranges=192.168.77.195-192.168.77.200
add name=pool-iptv-hosts ranges=192.168.77.50-192.168.77.150

# Damos de alta una nueva red para los hosts del nuevo bridge-iptv,
# y otra específica para los descos, con una dirección /30
/ip dhcp-server network
add address=192.168.77.0/24 comment="IPTV subnet for hosts" gateway=192.168.77.1 \
    netmask=24
add address=192.168.77.200/30 comment="IPTV subnet for descos" \
    dhcp-option=option_para_deco dns-server=172.26.23.3 gateway=192.168.77.1 \
    netmask=24

# Creamos un nuevo servidor dhcp, asociado al nuevo bridge-iptv
/ip dhcp-server
add address-pool=pool-iptv-hosts disabled=no interface=bridge-iptv name=dhcp-server-iptv

# Asignamos el vendor-class al nuevo servidor IPTV, para los descos
/ip dhcp-server vendor-class-id
add address-pool=pool-iptv-descos name="Movistar Descos" server=dhcp-server-iptv vid="[IAL]"

# Añadimos un cliente dhcp para obtener la IP del teléfono
/ip dhcp-client
add add-default-route=no disabled=no interface=voip-vlan3 use-peer-ntp=no

# Añadimos tres nuevas reglas al firewall para que funcionen las vlans,
# dos en el chain de input, para aceptar el tráfico de VoIP e IPTV
# y una en el chain de forward para prohibir el tráfico unicast que
# no esté ya nateado
/ip firewall filter
add action=accept chain=input comment="Accept vlan2 Iptv IGMP packets" \
    in-interface=iptv-vlan2 protocol=igmp \
    place-before=[find where chain=input and comment="defconf: drop invalid"]
add action=accept chain=input comment=\
    "Accept vlan2 & 3  (Iptv & Voip) multicast & broadcast traffic" \
    dst-address-type=!unicast in-interface-list=Vlan2&3 \
    place-before=[find where chain=input and comment="defconf: drop invalid"]
add action=drop chain=forward comment=\
    "Drop all new unicast traffic from vlan3 & 2 (Voip & Iptv) not DSTNATed" \
    connection-nat-state=!dstnat connection-state=new dst-address-type=\
    unicast in-interface-list=Vlan2&3

# Marcamos la prioridad de cada una de las VLANs, usando mangle, postrouting
# Además, creamos una lista para identificar las IPs de los los receptores
# de video bajo demanda, los descos.
/ip firewall mangle
add action=set-priority chain=postrouting comment="Prioritise Voip packets" \
    new-priority=5 out-interface=voip-vlan3 passthrough=yes
add action=set-priority chain=postrouting comment="Prioritise Iptv packets" \
    new-priority=4 out-interface=iptv-vlan2 passthrough=yes
add action=set-priority chain=postrouting new-priority=1 out-interface=\
    pppoe-out1
add action=add-src-to-address-list address-list=vod-receiver \
    address-list-timeout=1m chain=postrouting comment="RTSP - VOD Movistar" \
    dst-port=554 out-interface=iptv-vlan2 protocol=tcp

# Además del masquerade a la lista WAN (defconf), añadimos los masquerade
# para las vlans de voz e iptv, y para los hosts conectados al bridge IPTV
# El script añadirá una regla adicional de masquerade, para los descos
# que vienen de la lista vod-receiver, dada de alta en magle previamente
# con el comentario "VOD Script"
/ip firewall nat
add action=masquerade chain=srcnat comment=\
    "masq. vlan2 & vlan3 (Iptv & Voip)" out-interface-list=Vlan2&3
add action=masquerade chain=srcnat comment=\
    "masq. IPTV hosts" src-address=192.168.77.0/24

# Activamos el IGMP-Proxy
/routing igmp-proxy
set query-interval=30s quick-leave=yes

# Configuramos el IGMP-proxy para la interfaz vlan de IPTV y para ether2
/routing igmp-proxy interface
add alternative-subnets=0.0.0.0/0 interface=iptv-vlan2 upstream=yes
add interface=bridge-iptv

# Activamos RIP para VoIP e IPTV
/routing rip interface
add interface=voip-vlan3 passive=yes receive=v2
add interface=iptv-vlan2 passive=yes receive=v2
/routing rip network
add network=10.0.0.0/8
add network=172.26.0.0/16

# Script de Toniros para añadir la regla de src-NAT dinámicamente
/system script
add dont-require-permissions=no name=vod owner=admin policy=read,write \
    source=":local iplist [:len [/ip firewall address-list find list=\"vod-rec\
    eiver\"]]\
    \n:local rules [:len [/ip firewall nat find where comment=\"VOD Script\"]]\
    \n#:log info \"VODScript: IPs in list are \$iplist !\"\
    \n#:log info \"VODScript: Rules are \$rules !\"\
    \n:if (\$iplist = 0 and \$rules > 0) do={\
    \n\t#/ip firewall nat remove [find comment=\"VOD Script\"];\
    \n\t#:log info \"VODScript: Rule removed !\"\
    \n} else {\
    \n\t:local ipadressnew [/ip firewall address-list get [:pick [/ip firewall\
    \_address-list find list=\"vod-receiver\"] (\$iplist-1)] address]\
    \n\t:local ipadressold \"None\"\
    \n\t#:log info \"VODScript: IP address new is \$ipadressnew !\"\
    \n\t:if (\$iplist > 0 ) do {\
    \n\t\tif (\$rules > 0 ) do {\
    \n\t\t\t:set ipadressold [/ip firewall nat get [find comment=\"VOD Script\
    \"] to-addresses] \
    \n\t\t\t#:log info \"VODScript: IP address old is \$ipadressold !\"\
    \n\t\t}\
    \n\t\t:if (\$ipadressnew != \$ipadressold) do={\
    \n\t\t\tif (\$rules > 0 ) do {\
    \n\t\t\t\t/ip firewall nat remove [find comment=\"VOD Script\"];\
    \n\t\t\t}\
    \n\t\t\t/ip firewall nat add action=dst-nat chain=dstnat comment=\"VOD Scr\
    ipt\" dst-address-type=local in-interface=iptv-vlan2 to-addresses=\$ipadre\
    ssnew\
    \n\t\t\t:log info \"VODScript: IP address changed from \$ipadressold to \$\
    ipadressnew !\"\
    \n\t\t}\
    \n\t}\
    \n}"

# Programamos el script de VOD, para correr cada seis segundos
/system scheduler
add interval=6s name=vod on-event=vod policy=read,write start-time=startup
Gracias, un saludo!
 
add address=192.168.77.200/30 comment="IPTV subnet for descos" \ dhcp-option=option_para_deco dns-server=172.26.23.3 gateway=192.168.77.1 \ netmask=24
Hola, @pokoyo. Buenas noches!

Pues mira, sí. Me he tomado una cerveza a tu salud!!

A ver. Sólo he detectado un problema: es en la regla que te he señalado. Como has cambiado el rango del pool para los descos, add name=pool-iptv-descos ranges=192.168.77.195-192.168.77.200, la regla de la red de DHCP debería empezar en el origen del rango y abarcar por lo menos el rango completo, así (la máscara de /30 da para siete direcciones):

/ip dhcp-server network
add address=192.168.77.195/30 comment="IPTV subnet for descos" \
dhcp-option=option_para_deco dns-server=172.26.23.3 gateway=192.168.77.1 \
netmask=24

El resto creo que está bien. Gracias por el curro. Tómate una caña para celebrarlo!

Saludos!!!
 
Hola, @pokoyo. Buenas noches!

Pues mira, sí. Me he tomado una cerveza a tu salud!!

A ver. Sólo he detectado un problema: es en la regla que te he señalado. Como has cambiado el rango del pool para los descos, add name=pool-iptv-descos ranges=192.168.77.195-192.168.77.200, la regla de la red de DHCP debería empezar en el origen del rango y abarcar por lo menos el rango completo, así (la máscara de /30 da para siete direcciones):

/ip dhcp-server network
add address=192.168.77.195/30 comment="IPTV subnet for descos" \
dhcp-option=option_para_deco dns-server=172.26.23.3 gateway=192.168.77.1 \
netmask=24

El resto creo que está bien. Gracias por el curro. Tómate una caña para celebrarlo!

Saludos!!!

Ojo que un 192.168.20.200/30 son 4 equipos, si consideramos las direcciones de red y broadcast como usables [192.168.20.200-192.168.20.203].

¿Sería mejor así, para mis datos?
Código:
# Añadimos un nuevo pool para los descos,
# y otro para el resto de los hosts en ese bridge-iptv
/ip pool
add name=pool-iptv-descos ranges=192.168.77.200-192.168.77.203
add name=pool-iptv-hosts ranges=192.168.77.50-192.168.77.199

# Damos de alta una nueva red para los hosts del nuevo bridge-iptv,
# y otra específica para los descos, con una dirección /30
/ip dhcp-server network
add address=192.168.77.0/24 comment="IPTV subnet for hosts" gateway=192.168.77.1 \
    netmask=24
add address=192.168.77.200/30 comment="IPTV subnet for descos" \
    dhcp-option=option_para_deco dns-server=172.26.23.3 gateway=192.168.77.1 \
    netmask=24

Saludos, y mil gracias!
 
Ojo que un 192.168.20.200/30 son 4 equipos, si consideramos las direcciones de red y broadcast como usables [192.168.20.200-192.168.20.203].

¿Sería mejor así, para mis datos?
Código:
# Añadimos un nuevo pool para los descos,
# y otro para el resto de los hosts en ese bridge-iptv
/ip pool
add name=pool-iptv-descos ranges=192.168.77.200-192.168.77.203
add name=pool-iptv-hosts ranges=192.168.77.50-192.168.77.199

# Damos de alta una nueva red para los hosts del nuevo bridge-iptv,
# y otra específica para los descos, con una dirección /30
/ip dhcp-server network
add address=192.168.77.0/24 comment="IPTV subnet for hosts" gateway=192.168.77.1 \
    netmask=24
add address=192.168.77.200/30 comment="IPTV subnet for descos" \
    dhcp-option=option_para_deco dns-server=172.26.23.3 gateway=192.168.77.1 \
    netmask=24

Saludos, y mil gracias!
Huy! Perdona, me he liado y te he liado. Tienes razón. Es que como funcionaba, además...

A ver, /30, son 2 bits; o sea 2^2 = 4, menos la dirección 0 y la broadcast = 2 direcciones. Es decir, para no andar rácanos (por aquello de dejar margen para sustituciones de descos y no agotar el pool) deberíamos poner /29 -> 3 bits-> 2^3 = 8, menos 2 = 6 direcciones. -> 192.168.77.200/29 Y el pool dentro de este rango, por ejemplo: 192.168.77.200-192.168.77.206 (que son siete direcciones; pero si quieres ser purista, le reservamos también la de la red y le metemos seis, de la 201-206). ¿no es así?

Lo importante es que a los descos el DHCP le meta su option_para_desco, su gateway y su DNS, ¿no?. Como se lo estaba metiendo, me descuidé y calculé mal, perdona.

Ahora sí que deberíamos estar de acuerdo, ¿no?

Saludos y unas cañas!!
 
Lo cambio a /29 y mañana lo subo. Una más a la saca!

Saludos!
 
Sería necesario hacer un bridge para la VLAN2, 4 y 6 en el router movistar (en mi caso)?, en el caso de que quisiese solo la VLAN2 y 6, sería hacer un puente solamente en esos dos, verdad?

Saludos
 
Sería necesario hacer un bridge para la VLAN2, 4 y 6 en el router movistar (en mi caso)?, en el caso de que quisiese solo la VLAN2 y 6, sería hacer un puente solamente en esos dos, verdad?

Saludos

Tantas vlans quieras manejar en el mikrotik, tantas te toca borrar (que no poner en bridge) en la tabla de vlans del HGU.

Saludos!
 
Tantas vlans quieras manejar en el mikrotik, tantas te toca borrar (que no poner en bridge) en la tabla de vlans del HGU.

Saludos!
Muchas gracias. Lo intentaré probar hoy. Estos días no he podido hacer mucho.
Tantas vlans quieras manejar en el mikrotik, tantas te toca borrar (que no poner en bridge) en la tabla de vlans del HGU.

Saludos!
Buenas tardes,

Parece ser que no me funciona. No me conecta a internet y he tenido que volver a la configuración que tenía anteriormente.

No sé si lo estoy haciendo mal. He quitado las VLAN 2 y 6 del HGU tal y como me comentaste, y tengo un cable de red desde el HGU al ether1 del mikrotik donde he importado la config de NEW - Movistar Triple VLAN (Grupo Telefónica, España) [by @furny]
Configuración multi desco, multi-bridge, partiendo de la configuración base del quick set.
pero no consigo acceso al exterior.
 
Muchas gracias. Lo intentaré probar hoy. Estos días no he podido hacer mucho.

Buenas tardes,

Parece ser que no me funciona. No me conecta a internet y he tenido que volver a la configuración que tenía anteriormente.

No sé si lo estoy haciendo mal. He quitado las VLAN 2 y 6 del HGU tal y como me comentaste, y tengo un cable de red desde el HGU al ether1 del mikrotik donde he importado la config de NEW - Movistar Triple VLAN (Grupo Telefónica, España) [by @furny]
Configuración multi desco, multi-bridge, partiendo de la configuración base del quick set.
pero no consigo acceso al exterior.

¿Has partido de un reset del equipo con la configuración del quick set? Porque esa configuración se basa en meterla encima de la base, si partes de otra cosa, puede salir cualquier churro.

Si crees que sí, que lo has hecho bien, pásanos un export de la configuración que la veamos.

Saludos!
 
Arriba