MANUAL: Mikrotik, configuraciones básicas ISPs - RouterOS v7

Haré pruebas cuando vuelva a casa y os cuento, por si saco algo en claro.

Una vez creada la VLAN 50, cuales serian los siguientes pasas? Tendría que añadir la VLAN 50 al eth1 de la WAN?

Tengo un Bridge para la LAN con los puertos 2-3-4-5 y el puerto uno es para la WAN.

Estoy un poco perdido de cómo hacerlo, pero trasteare una vez realizar un backup.
El tema del IPTV es muy particular de cada proveedor. Como no tengas algo de referencia, chungo. ¿qué proveedor es, por curiosidad?

Saludos!
 
Es Agile TV y solo necesita internet para que su caja de TV funcione.
Es lo que me imaginaba pero no es así.
Hoy, por salir de dudas, quite el Mikrotik y active el router de Euskaltel y se ve correctamente.

En el momento que vuelvo a poner el Mikrotik la TV deja de funcionar, dice que no hay conexion a internet. En deco tiene internet porque youtube, acestream etc funcionan sin problemas.
 
Necesito a un valiente que haya actualizado ya a la 7.5 y quiera probar una cofig de tripleplay, para movistar.

Quién se anime, que me escriba por privado, que le paso la config. Una vez probada, la publicaremos aquí mismo.

Saludos!
 
Necesito a un valiente que haya actualizado ya a la 7.5 y quiera probar una cofig de tripleplay, para movistar.

Quién se anime, que me escriba por privado, que le paso la config. Una vez probada, la publicaremos aquí mismo.

Saludos!
Muchos cambios en 7.5? Que cambios quieres aplicar?
 
Hola,

creo que ya sabéis de qué va esto. Vamos a intentar recopilar las configuraciones básicas para echar a andar un mikrotik en las principales compañías proveedoras de internet en España, esta vez para la nueva versión de RouterOS v7, ahora que está considerada versión estable.
El post no es cosa mía, es cosa de todos, así que id compartiendo las configuraciones si os gusta ver este tipo de posts cuando os compráis un mikrotik y buscáis información a la desesperada. Es decir, esto no es sólo cosa mía, lo hacemos entre todos. De vuestra colaboración dependerá lo completo o incompleto que esté dicho post.

Como ya sabéis, todos estos setups parten de la configuración por defecto que monta el router vía el script de auto-configuración después de un reset sin marcar la opción del no default configuration.



Pepephone / MasMóvil / guuk. / Fibra Neba (sin teléfono) [by @pokoyo]

Conexión WAN: ONT Nokia G-010-G-P (Antigua ONT de Neba)​
Tipo de conexión WAN: DHCP​
VLAN Internet: 20​
VLAN Teléfono: N/A​
VLAN TV: N/A​

Configuración
Código:
# Damos de alta la vlan correspondiente, asociada al puerto físico que haga de WAN. Suponemos ONT / Router en bridge, conectada a ether1
/interface/vlan
add interface=ether1 name=internet vlan-id=20

# Creamos (o editamos el existente) cliente DHCP y la asignamos a esa nueva interfaz vlan
/ip/dhcp-client
add interface=internet

# Modificamos la lista WAN con la nueva interfaz de acceso a internet,
# para que apliquen correctamente las reglas de Firewall / NAT sobre ella
/interface/list/member
set [find where interface=ether1 and list=WAN] interface=internet



Movistar, O2 (Internet) [based on @stargate4you, updated by @pokoyo]
Conexión WAN:
ONT Huawei EG8120L
Tipo de conexión WAN: PPPoE: usuario (adslppp@telefonicanetpa) y contraseña (adslppp)
VLAN Internet: 6
VLAN Teléfono: N/A
VLAN TV: N/A

Configuración
Código:
# Dar de alta las vlan de internet. Suponemos ONT/Router bridge en ether1
/interface/vlan
add interface=ether1 name=vlan6-internet vlan-id=6

# Configurar la interfaz PPPoE para que use la vlan de internet
/interface/pppoe-client
add add-default-route=yes disabled=no interface=vlan6-internet \
  name=internet use-peer-dns=yes user=adslppp@telefonicanetpa \
  password=adslppp

# Modificamos la lista WAN con la nueva interfaz de acceso a internet,
# para que apliquen correctamente las reglas de Firewall / NAT sobre ella
/interface/list/member
set [find where interface=ether1 and list=WAN] interface=internet



Movistar, O2 (Internet + VoIP) [original from @stargate4you, updated by @pokoyo]
Conexión WAN:
ONT Huawei EG8120L
Tipo de conexión WAN: PPPoE: usuario (adslppp@telefonicanetpa) y contraseña (adslppp)
VLAN Internet: 6
VLAN Teléfono: 3
VLAN TV: N/A

Configuración
Código:
# Dar de alta las vlans 3 voip y 6 internet. Suponemos ONT/Router modo bridge, en ether1
/interface/vlan
add interface=ether1 name=vlan3-telefono vlan-id=3
add interface=ether1 name=vlan6-internet vlan-id=6

# Configurar la interfaz PPPoE para que use la vlan 6 internet
/interface/pppoe-client
add add-default-route=yes disabled=no interface=vlan6-internet \
  name=internet use-peer-dns=yes user=adslppp@telefonicanetpa \
  password=adslppp

# Modificamos la lista WAN con la nueva interfaz de acceso a internet,
# para que apliquen correctamente las reglas de Firewall / NAT sobre ella
/interface/list/member
set [find where interface=ether1 and list=WAN] interface=internet

# Crear un cliente DHCP para la vlan del teléfono, sin ruta por defecto.
# La ruta necesaria con distancia 120 la creará RIP, dinámicamente.
/ip/dhcp-client
add interface=vlan3-telefono add-default-route=no \
  use-peer-ntp=no use-peer-dns=no

# Aceptar el tráfico en el input del firewall, para que RIP funcione.
# Origen la vlan3-telefono, destino la dirección multicast 224.0.0.9,
# puerto 520 y tipo de tráfico UDP (RIPv2, RFC-2453). La colocamos
# delante de la regla general de DROP que hay en el chain de input.
/ip/firewall/filter
add action=accept chain=input comment="voip: accept rip multicast traffic" \
  in-interface=vlan3-telefono dst-address=224.0.0.9 dst-port=520 protocol=udp \
  place-before=[find where comment="defconf: drop all not coming from LAN"]

# Aplicar masquerade a la salida del VoIP, además de la lista WAN,
# que ya la trae por defecto. Esta regla iría justo debajo del otro masquerade.
/ip/firewall/nat
add action=masquerade chain=srcnat comment="voip: masq voip" \
    out-interface=vlan3-telefono

# Establecer la prioridad de las conexiones vlans (OPCIONAL)
/ip/firewall/mangle
add action=set-priority chain=postrouting new-priority=4 \
  out-interface=vlan3-telefono
add action=set-priority chain=postrouting new-priority=1 \
  out-interface=internet

# Creamos la instancia RIP para voip, para obtener las rutas dinámicas correspondientes a este servicio
/routing/rip/instance
add afi=ipv4 disabled=no name=rip
/routing rip interface-template
add instance=rip interfaces=vlan3-telefono mode=passive



Digimobil (Internet IPv4 + IPv6, Fibra Neba / SMART) [original from @diamuxin, updated by @pokoyo]
Conexión WAN:
ONT Huawei EchoLife HG8010H
Tipo de conexión WAN: PPPoE: Usuario (XXXXXXXX) y contraseña (YYYYYYYY) proporcionados por la operadora
VLAN Internet: 20
VLAN Teléfono: N/A
VLAN TV: N/A

Configuración
Código:
# Añadimos la VLAN del servicio de internet a la interfaz ether1
/interface/vlan
add interface=ether1 name=vlan20-internet vlan-id=20

# Creamos la conexión PPPoE, sobre la vlan previamente creada.
# Usuario y contraseña proporcionado por Digimobil desde atención al cliente previa solicitud.
# Usuario: XXXXXXXXX
# Contraseña: YYYYYYYYY
/interface/pppoe-client
add add-default-route=yes disabled=no interface=vlan20-internet \
  name=internet use-peer-dns=yes user=XXXXXXXXX@digi \
  password=YYYYYYYYY

# Modificamos la lista WAN con la nueva interfaz de acceso a internet,
# para que apliquen correctamente las reglas de Firewall / NAT sobre ella
/interface/list/member
set [find where interface=ether1 and list=WAN] interface=internet


################################
# Configuración IPv6 (OPCIONAL)
################################
# Activamos el cliente DHCP para solicitar la delegación de prefijos en la interfaz pppoe
/ipv6/dhcp-client
add add-default-route=no interface=internet pool-name=pool6 request=address,prefix

# Asignamos el pool6 de direcciones, creado automáticamente, a la interfaz bridge local
/ipv6/address
add from-pool=pool6 interface=bridge

# Reiniciamos la interfaz del PPPoE, para que nos empiece a entregar las direcciones IPv6
/interface/pppoe-client
set [find where name=internet] disabled=yes
/delay 5
/interface/pppoe-client
set [find where name=internet] disabled=no

Si además queremos seguir usando el teléfono, procederemos a crear un PPPoE fake sobre la vlan 20, asignando dicho servidor a un puerto ethernet concreto. Simplemente coged el siguiente código, editad las variables de entorno con vuestro usuario, contraseña y puerto dedicado donde irá conectado el router de Digi (importante, puerto fuera del bridge principal), llevadlo a un fichero pppoe-fake.rsc, subidlo al router (arrastrar y soltar el fichero en winbox) y corred desde terminal import pppoe-fake.rsc
Código:
######################################
############# VARIABLES ##############
######################################
:local usuario "usuario@digi"
:local password "p4ssw0rd"
# Importante: el puerto etherX ha
# de estar fuera del bridge principal
# X es el número de puerto, ej: ether5
:local puerto "etherX"
######################################

/interface vlan
add interface=$puerto name=vlan-wan-fake vlan-id=20
/ppp profile
add local-address=10.0.1.1 name=pppoe-fake remote-address=10.0.1.2
/ppp secret
add name=$usuario password=$password profile=pppoe-fake service=pppoe
/interface pppoe-server server
add default-profile=pppoe-fake disabled=no max-mtu=1492 max-mru=1492 \
  interface=vlan-wan-fake service-name=pppoe-server-fake

Vodafone / Lowi Neba (Internet) [original from @Dexter91 & @ectoplasma, updated by @pokoyo]
Conexión WAN:
ONT Nokia G-010G-P
Tipo de conexión WAN: PPPoE: Usuario (XXXXXXXX) y contraseña (YYYYYYYY) extraidos del router de la operadora. Info aquí
VLAN Internet: 24 / 20
VLAN Teléfono: N/A
VLAN TV: N/A

Configuración
Código:
# Añadimos la VLAN del servicio de internet (24 normalmente, aunque también puede venir por la 20)
/interface/vlan
add interface=ether1 name=vlan2x-internet vlan-id=24

# Configurar la interfaz PPPoE para que use la vlan2x-internet
# Usuario y contraseña extraídos de los equipos originales de Vodafone / Lowi
# Usuario: XXXXXXXXX
# Contraseña: YYYYYYYYY
/interface/pppoe-client
add add-default-route=yes disabled=no interface=vlan2x-internet \
  name=internet use-peer-dns=yes user=XXXXXXXXX \
  password=YYYYYYYYY

# Modificamos la lista WAN con la nueva interfaz de acceso a internet,
# para que apliquen correctamente las reglas de Firewall / NAT sobre ella
/interface/list/member
set [find where interface=ether1 and list=WAN] interface=internet

Euskatel, sobre fibra MasMóvil (sin teléfono) [by @mendizalea]
Conexión WAN: ZTE F6640 (bridge mode)​
Tipo de conexión WAN: DHCP​
VLAN Internet: 10​
VLAN Teléfono: N/A​
VLAN TV: N/A​

Configuración
Código:
# Damos de alta la vlan correspondiente, asociada al puerto físico que haga de WAN. Suponemos ONT / Router en bridge, conectada a ether1
/interface/vlan
add interface=ether1 name=internet vlan-id=10

# Creamos (o editamos el existente) cliente DHCP y la asignamos a esa nueva interfaz vlan
/ip/dhcp-client
add interface=internet

# Modificamos la lista WAN con la nueva interfaz de acceso a internet,
# para que apliquen correctamente las reglas de Firewall / NAT sobre ella
/interface/list/member
set [find where interface=ether1 and list=WAN] interface=internet

...

Id enviándolas, y las vamos publicando.

Gracias, un saludo!
En cuanto ponga el de Vodafone en bridge comparto como se queda a ver si puedo
 
Hola, se podria añadir DIGI con las VLAN Internet y telefono?
La tienes? yo añado lo que sea que me paséis. Pero obviamente no me puedo inventar las de operadores que no tengo!

Para DiGi tienes explicado cómo hacer la trampa y colocar el router que te dan detrás del mikrotik, para mantener el teléfono, vía un fake PPPoE server.

Saludos!
 
Pues listo, ya tenéis la config de triple play de movistar publicada. Recordad que, para que funcione, el router ha de estar en la versión 7.5 o superior.

Saludos!

Muchas gracias.

Otro argumento más para utilizar los equipos de Mikrotik con la IPTV de Movistar.

Saludos.
 
Hola @pokoyo , una duda, con la triceplay cuando intento crear un certificado con letsencrypt no consigo que llegue al servidor web del mikrotik

he abierto el firewall para el puerto 80 input pero estoy comprobando que la navegación desde fuera no llega

¿Qué me puede estar faltando?
 
Hola @pokoyo , una duda, con la triceplay cuando intento crear un certificado con letsencrypt no consigo que llegue al servidor web del mikrotik

he abierto el firewall para el puerto 80 input pero estoy comprobando que la navegación desde fuera no llega

¿Qué me puede estar faltando?
Qué tiene que ver eso con la config de triple play? Estás abriendo correctamente el tráfico al router del puerto 80 y 443?

Saludos!
 
Qué tiene que ver eso con la config de triple play? Estás abriendo correctamente el tráfico al router del puerto 80 y 443?

Saludos!
Hola, no tiene nada que ver

en el script anterior tenía puesto que el servicio www respondiese a la 0.0.0.0/0 y me había olvidado de ponerlo en este

Con eso todo ok, ya recibí el certificado

LLevo con esta config una semana y va muy bien, primero probé en el hap ac2 y ahora en el 951

gracias @pokoyo
 
Tras meses, casi un año, voy a poder montar el Mikrotik en casa (reforma interminable). Viendo lo que tengo, M+ con 3 descos (1 cableado y 2 por Wi-Fi) quería probar la Triple Play que has publicado.
De cara a gestionar la ONT, alguna preferencia, tengo una HG8240H de Huawei y una Ubiquiti Loco, entiendo que con cualquiera de las dos funcionará.
Gracias
 
Tras meses, casi un año, voy a poder montar el Mikrotik en casa (reforma interminable). Viendo lo que tengo, M+ con 3 descos (1 cableado y 2 por Wi-Fi) quería probar la Triple Play que has publicado.
De cara a gestionar la ONT, alguna preferencia, tengo una HG8240H de Huawei y una Ubiquiti Loco, entiendo que con cualquiera de las dos funcionará.
Gracias
Prueba primero la Huawei, que está certificada. Las Ubiquiti dieron mucha guerra en el pasado con el tema del multicast, no sé si los firmwares nuevos lo corrigen.

Saludos!
 
Arriba