MANUAL: Mikrotik, el amigo gorrón [IPTV pululante]

Buenas estoy teniendo microcortes en el tunel, cada X segundos se cae y vuelve. ¿Algo que se me haya podido pasar?
 
Hola!

He configurado PEPE y PACO siguiendo el manual, pero parece que el túnel no termina de levantar. Desde PACO hago ping a 172.17.0.1 y desde PEPE hago ping a 172.17.0.2. Pero aunque en PACO tengo RS en el bridge-iptv, no es así en PEPE. Además, si pincho un portátil al puerto eth2 en PEPE, no se asigna una IP de PACO.

PEPE
uwvxsfl.png


PACO
OO6sWpQ.png


Dejo los exports para ver si alguien puede echarme una mano, porque por más que le doy vueltas no consigo dar con el problema. Muchas gracias!

PEPE
Código:
# nov/11/2022 16:20:42 by RouterOS 7.6
# software id = P2CH-BSB7
#
# model = RB750Gr3
# serial number = HCM07RVAZKB
/interface bridge
add admin-mac=DC:2C:6E:FA:07:B2 auto-mac=no comment=defconf name=bridge
add igmp-snooping=yes name=bridge-iptv
/interface eoip
add local-address=172.17.0.1 mac-address=FE:9B:0D:26:C3:07 mtu=1500 name=\
    eoip-iptv remote-address=172.17.0.2 tunnel-id=0
/interface wireguard
add listen-port=54321 mtu=1420 name=wg-sts-iptv
/interface list
add comment=defconf name=WAN
add comment=defconf name=LAN
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip hotspot profile
set [ find default=yes ] html-directory=hotspot
/ip pool
add name=default-dhcp ranges=192.168.88.10-192.168.88.254
/ip dhcp-server
add address-pool=default-dhcp interface=bridge name=defconf
/port
set 0 name=serial0
/interface bridge port
add bridge=bridge-iptv comment=defconf interface=ether2
add bridge=bridge comment=defconf interface=ether3
add bridge=bridge comment=defconf interface=ether4
add bridge=bridge comment=defconf interface=ether5
/ip neighbor discovery-settings
set discover-interface-list=LAN
/interface list member
add comment=defconf interface=bridge list=LAN
add comment=defconf interface=ether1 list=WAN
/interface wireguard peers
add allowed-address=172.17.0.2/32 comment=gorron-iptv endpoint-address=\
    XXXXXX.sn.mynetname.net endpoint-port=54321 interface=wg-sts-iptv \
    public-key="7yaivnie9NVE5/44RSriuRoHKZAf7HP6VCrK+ncYkWI="
/ip address
add address=192.168.88.1/24 comment=defconf interface=bridge network=\
    192.168.88.0
add address=172.17.0.1/30 interface=wg-sts-iptv network=172.17.0.0
/ip cloud
set ddns-enabled=yes
/ip dhcp-client
add comment=defconf interface=ether1
/ip dhcp-server network
add address=192.168.88.0/24 comment=defconf dns-server=192.168.88.1 gateway=\
    192.168.88.1
/ip dns
set allow-remote-requests=yes
/ip dns static
add address=192.168.88.1 comment=defconf name=router.lan
/ip firewall nat
add action=masquerade chain=srcnat comment="defconf: masquerade" \
    ipsec-policy=out,none out-interface-list=WAN
/ipv6 firewall address-list
add address=::/128 comment="defconf: unspecified address" list=bad_ipv6
add address=::1/128 comment="defconf: lo" list=bad_ipv6
add address=fec0::/10 comment="defconf: site-local" list=bad_ipv6
add address=::ffff:0.0.0.0/96 comment="defconf: ipv4-mapped" list=bad_ipv6
add address=::/96 comment="defconf: ipv4 compat" list=bad_ipv6
add address=100::/64 comment="defconf: discard only " list=bad_ipv6
add address=2001:db8::/32 comment="defconf: documentation" list=bad_ipv6
add address=2001:10::/28 comment="defconf: ORCHID" list=bad_ipv6
add address=3ffe::/16 comment="defconf: 6bone" list=bad_ipv6
/system clock
set time-zone-name=Europe/Madrid
/tool mac-server
set allowed-interface-list=LAN
/tool mac-server mac-winbox
set allowed-interface-list=LAN

PACO
Código:
# nov/11/2022 16:08:54 by RouterOS 7.6
# software id = 5I1A-0M3K
#
# model = RB750Gr3
# serial number = CC210F6B6460
/interface bridge
add igmp-snooping=yes name=bridge-iptv
add admin-mac=DC:2C:6E:AA:D6:72 auto-mac=no name=bridge-lo
/interface eoip
add local-address=172.17.0.2 mac-address=FE:80:C8:A3:41:3F mtu=1500 name=\
    eoip-iptv remote-address=172.17.0.1 tunnel-id=0
/interface wireguard
add listen-port=14310 mtu=1420 name=wg-sts-iptv
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/ip hotspot profile
set [ find default=yes ] html-directory=hotspot
/ip pool
add name=pool-lo ranges=192.168.79.2-192.168.79.254
/ip dhcp-server
add address-pool=pool-lo interface=bridge-lo name=dhcp-lo
/port
set 0 name=serial0
/interface bridge port
add bridge=bridge-lo interface=ether2
add bridge=bridge-iptv interface=ether1
add bridge=bridge-iptv interface=eoip-iptv
/interface wireguard peers
add allowed-address=0.0.0.0/0 endpoint-address=XXXXXXXX.sn.mynetname.net \
    endpoint-port=54321 interface=wg-sts-iptv persistent-keepalive=25s \
    public-key="fkFQZvmjmVzCWFbawULEzjopxbSs7FyQXnzHYox0NDs="
/ip address
add address=192.168.79.1/24 interface=bridge-lo network=192.168.79.0
add address=172.17.0.2/30 interface=wg-sts-iptv network=172.17.0.0
/ip cloud
set ddns-enabled=yes update-time=no
/ip dhcp-client
add interface=bridge-iptv
/ip dhcp-server network
add address=192.168.79.0/24 gateway=192.168.79.1
/ip dns
set servers=1.1.1.1,1.0.0.1
/ip route
add dst-address=192.168.2.1/24 gateway=172.17.0.1
/system clock
set time-zone-name=Europe/Madrid
/system identity
set name=MikroTik-PACO
 
@fran1985

En Pepe te falta meter en el bridge-iptv la interfaz de eoip (eoip-iptv)

Saludos.
Cooorrecto.

Saludos!
Pues efectivamente, ese el problema, muchas gracias! Menuda tonteria... el script había fallado en el comando add bridge=bridge-iptv interface=ether2, no ejecutó la siguiente instrucción, y no me dí cuenta.

De todas maneras, he hecho un test de velocidad conectando al puerto ether2, y apenas da 30mbps. Es raro porqué en paco hay 600mb y en pepe 1000mb. ¿Puede ser por tener doble NAT al haber en pepe un router neutro detrás del router de fibra del operador?
 
Pues efectivamente, ese el problema, muchas gracias! Menuda tonteria... el script había fallado en el comando add bridge=bridge-iptv interface=ether2, no ejecutó la siguiente instrucción, y no me dí cuenta.

De todas maneras, he hecho un test de velocidad conectando al puerto ether2, y apenas da 30mbps. Es raro porqué en paco hay 600mb y en pepe 1000mb. ¿Puede ser por tener doble NAT al haber en pepe un router neutro detrás del router de fibra del operador?
Es por el cifrado del túnel y el consiguiente procesado en ambos extremos. 30 Mb/s es más que suficiente, la verdad.
 
Es por el cifrado del túnel y el consiguiente procesado en ambos extremos. 30 Mb/s es más que suficiente, la verdad.
Aha, entonces sin problema. Me parecía haber leído páginas atrás que para HD y UHD hacían falta al menos 50bmps. En unos días recibo el desco y podré probarlo. Gracias!
 
Buenos días a todos.

Hacía tiempo que no me pasaba por aquí porque he estado bastante liado y madre mía la de mensajes que hay.

Vengo a contaros una vuelta de tuerca al tema de Paco y Pepe.

Este post está montado para que Pepe ponga un deco en su casa y está perfecto. La vuelta de tuerca viene que Movistar si estás conectado desde el router de Paco no te pide credenciales para conectarte a su televisión porque detectas que estás en su red.

Como en nuestro caso hemos trasladado la red de Paco a casa de Pepe a un puerto o una wifi, a dicha wifi podemos conectar ordenadores, tablets o televisiones que cuando accedan a Movistar no les van a pedir credenciales por lo que podrías ver los contenidos sin necesidad de tener deco.

Imagino que a más de uno ya se os habrá ocurrido pero aquí lo dejo por si alguien no había caído en la cuenta.

Saludos.
 
Buenas a todos.

Os voy a contar una historia real.

A Paco se le ha estropeado la línea de fibra o el router, hasta aquí bien no deja de ser una avería.

Se presenta un técnico hace sus comprobaciones y llama también para ver si es avería interna o externa. Al final se soluciona el problema cambiando el router y de paso instalando un nuevo decodificador UHD.

Ve un cable naranja que está conectado al HGU y pregunta que es. Es el cable de red que conecta el HGU con el hAP AC2 que hace de AP WiFi más el servidor Wireguard + Eoip.

Bueno, pues según él ese era el problema de la avería, que interfiere el Mikrotik en el buen funcionamiento de la red.
Cuando me lo ha contado Paco me he quedado a cuadros. Por lo visto el Mikrotik era una ladrón de no se qué le ha dicho.

En fin, cosas que pasan.

A ver si cuando vaya yo este fin de semana a casa de Paco a poner en orden todo ( abrir puertos en el nuevo HGU y modificar la ssid en el hAP AC2) no me roban la cartera estos de Mikrotik. ;-)

Saludos.
 
Buenas a todos.

Os voy a contar una historia real.

A Paco se le ha estropeado la línea de fibra o el router, hasta aquí bien no deja de ser una avería.

Se presenta un técnico hace sus comprobaciones y llama también para ver si es avería interna o externa. Al final se soluciona el problema cambiando el router y de paso instalando un nuevo decodificador UHD.

Ve un cable naranja que está conectado al HGU y pregunta que es. Es el cable de red que conecta el HGU con el hAP AC2 que hace de AP WiFi más el servidor Wireguard + Eoip.

Bueno, pues según él ese era el problema de la avería, que interfiere el Mikrotik en el buen funcionamiento de la red.
Cuando me lo ha contado Paco me he quedado a cuadros. Por lo visto el Mikrotik era una ladrón de no se qué le ha dicho.

En fin, cosas que pasan.

A ver si cuando vaya yo este fin de semana a casa de Paco a poner en orden todo ( abrir puertos en el nuevo HGU y modificar la ssid en el hAP AC2) no me roban la cartera estos de Mikrotik. ;-)

Saludos.
Echarle la mierda a otro es gratis, ya sabes. Y, basta que vean algo que no conozcan, para que digan "date, esto es!" Peo vamos, que si te cuento las caras que me han puesto a mi cuando me vienen a vender fibra a la puerta de casa y les empiezo a hablar de redes... flipas. Y, cuando les abro la caja de comunicaciones, directamente salen corriendo.

Suerte que tu Paco no le ha dado por contarle para qué valía el invento, sino lo mismo le explota la cabeza al técnico :D

Saludos!
 
Suerte que tu Paco no le ha dado por contarle para qué valía el invento, sino lo mismo le explota la cabeza al técnico :D

Ya ves, un switch con AP wifi a la vista de todos. Para conectar la PS4 y tener wifi en la otra punta del piso.

Pues es el culpable según el técnico.
Además le dijo que lo tenga desconectado y enchufe la PS4 directamente. Claro, claro y nos quedamos sin WiFi en este extremo del piso. Como Paco no tiene idea de estos temas pues tampoco saben que responder. Hasta les da "miedo" volver a conectarlo como antes.
Este fin de semana cuando vaya veremos si ocurre algo "paranormal".

Saludos.
 
Buenas tardes.
LLevo varias semanas con el mikrotik y me quedaba el punto de realizar el bonustrack. Ya que por las noches apago el router y cuando lo enciendo me encuentro que me tengo que conectar en remoto para reinciar la interfaz wireguard.

En el HGU de Paco le he creado una reserva estatica de ip y le he abierto el puerto UDP por el que escucha la interfaz wireguard. En pepe la conexion apunta a la ddns de Paco y apunta al puerto destino por el que escucha Paco. He hecho pruebas reiniciando equipos y nada no hay manera de que se conectene automaticamente, sin que se se tenga que reiniciar la interfaz.

+Tengo los keepalives desactivados

Para conectarme a Paco en remoto lo hago a traves del winbox, cambie el puerto del servicio y realice la correspondiente apuerta de puertos en el HGU y me funciona ok

Lo que me ha resultado raro y no se el motivo es que en el HGU de Paco tengo abiertos los siguientes puertos ej:

Winbox :2222
Wireguard:3333

Cuando hago un escaneo de puertos de 2222 y 3333 desde la pagina web "hidemy.name" me aparece el puerto del wireguard cerrado...

En Paco no tengo reglas firewall , asi que no se mucho que es lo que me esta haciendo para que no se conecte automaticamente..

Si alguien me puede orientar, lo agradezo gracias.

La version en ambos equipos es 7.6



****Solucionado casi al momento de escribir que se me olvido de ver esto-->


No tenia el fw bien actualizado en Paco -->

System (menú) >> RouterBOARD (submenú) >>

Un saludo
 
Última edición:
Hola!

Introducción​

Os os vengo a traer un manual muy sencillo y divertido, que creo va a ser un bombazo, precisamente por la simpleza del mismo. Y, de paso, para ahorrarnos unos duros, que siempre viene bien. El propósito del post es meramente educativo, no quiero incitar a nadie a cometer nada ilegal y, por descontado, no me responsabilizo de lo que hagáis con ello, así que consultad vuestros contratos de servicio para aseguraos que no cometéis ninguna ilegalidad.

El propósito del manual es muy simple: ver IPTV en un domicilio distinto a donde lo tenemos contratado, SIN TENER NI PAJOTERA IDEA DE MIKROTIK (o casi), partiendo de la siguiente premisa: el setup del operador, no se toca. Es decir, vamos a montar algo que, sin manipular en absoluto el router que nos instala nuestro operador y que funciona flamante con su servicio de IPTV, sea capaz de teletransportar el servicio de tv a otro lugar. La idea mola, ¿verdad? Pues al lío.

Os presento a Paco y Pepe, dos colegas. Paco es abonado al servicio de televisión IPTV del operador dominante en su región y tiene cero conocimiento de qué narices es un Mikrotik (le suena a ruso, pero poco más puede decir). Pepe, es un apasionado de la marca, y algo manitas en la materia, fiel seguidor de este foro y sus manuales. Pepe, lleva tiempo dándole vueltas a una cosa: ¿sería capaz de transportar el servicio de televisión IPTV de Paco, sin causarle a este molestia alguna? Porque claro, Paco ni tiene ni papa del tema, y lo de cambiar su flamante router del operador por un mikrotik... como que no. Pero Pepe, que es muy insistente, lleva tiempo devanándose los sesos pensando, ¿seré capaz de montar un router mikrotik tonto, que sea capaz de, conectado el router de Paco, obtener y transportar dicho servicio? ¿Me podría valer el nuevo tipo de túnel WireGuard para ello? Pues ya os adelanto, que Pepe ha triunfado... pero bien.

Premisas y materiales​

Pepe tiene en su casa una infraestructura de la hostia, montada con Mikrotik, como buen aficionado a la marca. Su flamante router Letón comanda su casa y, por allí tirado, tiene un viejo mAP [RBmAP2nD] al que no sabe qué uso darle. También, ha conseguido hacerse de un desco de la operadora que usa Paco, el cual funciona fantástico en casa de Paco, pero claro, se le hace un poco incómodo irse a ver la tele allí. Pepe, que es algo gorrón pero muy generoso, ha pensado en regalarle el mAP a Paco, previamente configurado para teletransportar dicho servicio. Sin más, pasamos a ver las sencilla configuraciones con las que Pepe ha conseguido ver la TV de Paco, cómodamente desde su casa. Para ello, Pepe va a hacer uso de todo el conocimiento que ha adquirido leyendo este foro, y va a poner en práctica una combinación ganadora: WireGuard + EoIP. Lo que pretende es que un desco conectado a un puerto concreto del router de su casa, se teletransporte a casa de Paco como si estuviera allí mismo conectado. Pero, y aquí viene la miga del asunto, sin tocar para nada el equipamiento de Paco.

Configuración​

Empezaremos con la configuración del router de Pepe. Partiendo de la configuración básica, Pepe sólo ha tenido que hacer un par de cosas para que esto funcione
  • Montar un túnel WireGuard entre el router de su casa y el mAP
  • Montar un EoIP encima de ese túnel, sobre las direcciones /30 que WireGuard para dicho túnel
  • Añadir un nuevo bridge con igmp-snooping y meter en ese bridge el puerto donde va a conectar el desco, más el EoIP anterior.
Sin más, esta sería la configuración adicional de Pepe
Código:
#######################################
########## ROUTER DE PEPE #############
#######################################

############## WIREGUARD ##############
# Creamos una nueva interfaz para este propósito
/interface/wireguard
add listen-port=54321 name=wg-sts-iptv
# Creamos un nuevo peer que representa al router gorrón
# La public key la cogemos de la interfaz de dicho router
# remoto, el router gorrón
/interface/wireguard/peers
add allowed-address=172.17.0.2/32 \
  comment=gorron-iptv interface=wg-sts-iptv \
  public-key="PUBLIC_KEY_PACO"

########### DIRECCIONAMIENTO ##########
# Creamos la dirección /30 de este lado del túnel
/ip/address
add address=172.17.0.1/30 interface=wg-sts-iptv

######### EoIP SOBRE LAS /30 ##########
# Creamos un nuevo túnel EoIP
/interface/eoip
add local-address=172.17.0.1 name=eoip-iptv \
  remote-address=172.17.0.2 tunnel-id=0 mtu=1500

########### NUEVO BRIDGE IPTV ##########
# Creamos el nuevo bridge con igmp-snooping
/interface/bridge
add igmp-snooping=yes name=bridge-iptv
# Metemos los puertos involucrados, desco = ether2
/interface/bridge/port
set [find interface=ether2] bridge=bridge-iptv
add bridge=bridge-iptv interface=eoip-iptv

############## FIREWALL  ##############
# Aceptamos en input la conexión del router remoto
/ip firewall filter
add action=accept chain=input dst-port=54321 \
protocol=udp comment="vpn: allow wireguard gorron" \
place-before=[find comment="defconf: drop all not coming from LAN"]
# Aceptamos también el tráfico del EoIP en input,
# especialmente útil si la comunicación no es bi-direccional
add action=accept chain=input comment="iptv: allow gre for eoip" \
    in-interface=wg-sts-iptv protocol=gre place-before=\
    [find comment="defconf: drop all not coming from LAN"]

Listo su router, Pepe va a preparar el mAP que con todo el cariño le va a regalar a su amigo Paco. En este caso, en lugar de partir de una configuración por defecto, Pepe ha decidido montar un router tonto, que se va a comportar como un switch en casa de Paco, tal que sea enchufar y listo. Es decir, Pepe ha partido, para este equipo, de un reset sin configuración. Ese router, una vez encendido y conectado al router de Paco, llamará a casa de Pepe para enlazar ambos equipos vía WireGuard. Establecido dicho enlace, se levantará un segundo túnel EoIP, capaz de teletransportar el segmento de L2 del router de Paco, tal que el desco remoto en casa de Pepe crea que está efectivamente conectado al router de la operadora en casa de Paco. Y, es resto, es coser y cantar...
Código:
#######################################
########## ROUTER DE PACO #############
#######################################

############## VARIABLES ##############
:local puertoWireguardPepe "54321"
:local publicKeyWireguardPepe "PUBLIC_KEY_PEPE="
:local subredLanPepe "192.168.88.0/24"
:local direccionDDNSPepe "pepe.pericopalotes.com"
:local nombreRouterPaco "gorron"

############## WIREGUARD ##############
# Creamos una nueva interfaz para este propósito
# Obviamos el puerto, no lo vamos a usar
/interface/wireguard
add name=wg-sts-iptv
# Creamos un nuevo peer que representa el router de Pepe
# La public key la cogemos de la interfaz
# wireguard-sts-iptv del router remoto.
# Modificamos el endpoint por la dirección cloud de Pepe
/interface/wireguard/peers
add allowed-address=0.0.0.0/0 endpoint-address=\
  $direccionDDNSPepe endpoint-port=$puertoWireguardPepe \
  interface=wg-sts-iptv \
  public-key=$publicKeyWireguardPepe \
  persistent-keepalive=25s

######### EOIP SOBRE LAS /30 ##########
# Creamos un nuevo túnel EoIP
/interface/eoip
add local-address=172.17.0.2 name=eoip-iptv \
  remote-address=172.17.0.1 tunnel-id=0 mtu=1500

############ NUEVOS BRIDGES ###########
# Creamos el nuevo bridge con igmp-snooping para IPTV,
# además del bridge normal del router que usaremos
# como interfaz de loopback, para administración
/interface/bridge
add admin-mac=[/interface/ethernet/get ether2 mac-address] \
    auto-mac=no name=bridge-lo
add igmp-snooping=yes name=bridge-iptv
# Metemos cada puerto en su sitio, ether1 = router del operador
# ether2 = lo reservamos como puerto de administración
# si queremos aprovechar todos los puertos como switch,
# metermos todos ellos en el bridge iptv +  el túnel EoIP
/interface/bridge/port
add bridge=bridge-lo interface=ether2
add bridge=bridge-iptv interface=ether1
add bridge=bridge-iptv interface=eoip-iptv

########### DIRECCIONAMIENTO ##########
# Direccionamos el bridge loopback y el túnel
/ip/address
add address=192.168.79.1/24 interface=bridge-lo
add address=172.17.0.2/30 interface=wg-sts-iptv

########## DHCP ADMINISTRACION  #######
/ip/pool
add name=pool-lo ranges=192.168.79.2-192.168.79.254
/ip/dhcp-server
add address-pool=pool-lo interface=bridge-lo name=dhcp-lo
/ip/dhcp-server/network
add address=192.168.79.0/24 gateway=192.168.79.1

####### CREAMOS LA INTERFAZ WAN #######
# Nuestra WAN = bridge-iptv, como switch que somos
# Levantaremos un cliente DHCP para obtner IP
# y salida a internet, para poder llamar a casa
# obtendremos una ruta por defecto y un DNS
/ip/dhcp-client
add interface=bridge-iptv

########## DNS SERVER BACKUP ##########
# Le damos  un DNS de backup, por si nos
# falla el que entregue el cliente DHCP
/ip/dns
set servers=1.1.1.1,1.0.0.1

############ RUTA ESTÁTICA ############
# Esto le permitirá a Pepe administrar
# el router gorrón en remoto. Suponemos
# 192.168.88.0/24 segmento pricipal LAN
# de Pepe el cual alcanzamos al otro lado
# del túnelWireGuard, 172.17.0.1
/ip/route
add dst-address=$subredLanPepe gateway=172.17.0.1

############### WIRELESS  #############
# Como no lo usamos, lo desactivamos
/interface/wireless
set [find] disabled=yes

############ HORA Y NOMBRE ############
# Establecemos la franja horaria del equipo
/system/clock
set time-zone-name=Europe/Madrid
# y le damos un nombre
/system/identity
set name=$nombreRouterPaco

Y, con esto y un bizcocho, hemos aprendido una vez más a a sacarle partido a la tecnología que nos ofrecen los equipos Mikrotik. Esto os puede valer para llevaros el servicio a una segunda residencia, de vacaciones, etc. O, como Pepe, para ser un gorrón y ver la TV de Paco.

Los resultados de este setup son espectaculares. El tráfico Multicast gasta 7Mbps, y sube hasta los 10-12Mbps viendo contenido, para el proveedor que he podido probar. El mAP se mantiene por debajo del 30% de CPU... un equipo con 650 MHz y 64MB de RAM. Me parece, sencillamente, brillante.

PS: agradecimientos, a @roolezz por prestarse a probar todas las locuras que se me pasan por la cabeza con estos setups, él fue quien me dio la chispa para saber que esto podía funcionar, haciendo una prueba rápida en su casa, sin ella no me habría aventurado a probarlo a fondo.
También muy especial agradecimiento para J.E.D y R.G.U. por su amabilidad a la hora de prestarme su servicio de IPTV para la puesta en producción de este manual, los cuales han hecho de "amigo Paco" en este asunto. Sois los mejores chicos ;)

Bonus track: comunicación bidireccional

En el hipotético caso de que tengamos confianza más que de sobra con Paco, Pepe puede montar una configuración incluso más estable que la anterior, haciendo la comunicación bidireccional. Esto implica dos cosas: conocer la IP pública de Paco (lo tenemos solucionado con el ddns de mikrotik) y abrir el puerto correspondiente a la interfaz de WireGuard en su router de operadora.
Lo primero, activamos el IP Cloud en el equipo que le regalemos a Paco.
Código:
/ip/cloud
set ddns-enabled=yes

Acto seguido, obtenemos los datos del DDNS y del puerto de WireGuard que tenemos en el router de Paco, que nos harán falta más adelante:
Código:
:put ("ddns: " . [/ip/cloud get dns-name])
:put ("puerto: " . [/interface/wireguard get [find name=wg-sts-iptv] listen-port])

Con estos dos datos, podemos modificar el peer de Paco en Pepe, para que apunte a dicha dirección y puerto. Supongemos que hemos obtenido una dirección DNS tal que xxxyyyzzz.sn.mynetname.net y un puerto 12345. Los cambios en el peer serían los siguientes:
Código:
/interface/wireguard/peers set [find comment=gorron-iptv] \
  endpoint-address=xxxyyyzzz.sn.mynetname.net endpoint-port=12345

Y, como último paso, tenemos que entrar en el router de la operadora y hacer dos cosas:
  • Fijar la IP que el DHCP le otorga a nuestro router gorrón (o configurar una IP + ruta estática en el mikrotik), con un lease estático.
  • Abrir el puerto que obtuvimos, de la interfaz WireGuard de Paco, y redireccionarlo a la IP estática o dinámica reservada que tenga el Mikrotik.

Con estos dos cambios, sería seguro quitar el "keep-alive" del peer de Pepe en Paco, puesto que ambos routers empezarían a llamarse entre sí en caso de pérdida de conexión, y se encontrarían más temprano que tarde. Gracia al compi @huzoaaz por la sugerencia del bonus track de este manual, y por su ofrecimiento a probar todas estas configuraciones ;)

Espero que lo disfrutéis, un saludo!

Buenas @pokoyo:

Estoy leyendo este tutorial y me gustaría exponerte mi caso para saber si es posible implementarlo.

Actualmente dispongo en mi hogar de servicio de IPTV proporcionado por un ASUS (sustitui el de la operadora por una ONT+Router Asus en su dia).

Me gustaría poder visionar la TV en una segunda residencia pero no me queda muy claro cual seria la solución optima.

Por un lado con tu tutorial creo que una posible solución seria dejar el router de la operadora en mi primera residencia y conectarle el mAp 2nd detras del mismo con el tunel Wireguard + EoIP. En este caso recogería el ASUS de mi vivienda original para sustituir el router de la operadora en la segunda residencia y conectarle otro mAp 2nd detras con el tunel Wireguard (no me queda muy claro con el tutorial si en la segunda residencia hay que colocar un mAp u otro router superior).

La otra posible solución creo que seria colocar en la vivienda principal el router mAp detras del router Asus (ONT-Router ASUS-Router mAp) si es que esto es posible, y en la segunda residencia el router mAp detras del router de la operadora o bien sustituir el router de la operadora por otro router de Mikrotik superior (aqui tendrias que aconsejarme un modelo) si este caso permite realizar la IPTV pululante.

¿Podrias indicarme si es correcto y que caso seria mas aconsejable? Todavia no he realizado la inversión en los Mikrotik porque no tengo clara la estructura.

Un saludo y muchas gracias por adelantado.
 
Segunda opción: equipo mikrotik en modo bridge debajo del Asus + Mikrotik como principal en el otro extremo, este último, de tu elección (un hAP-ac3 puede ser buen candidato).

Saludos!
 
Hola de nuevo.
Después de unas semanas con problemas físicos, he retomado el tema de Pepe2, pero me falla, creo que he detectado error pero no consigo crear el brigde iptv para esta nueva interfaz.
Me explico mejor con esta imagen:
bridge.png


Cuando intento ejecutar desde winbox esto:
/interface bridge port
add bridge=bridge-iptv-2 interface=eoip-iptv-2
Me responde:
input does not match any value of bridge
Gracias y saludos.
 
Obviamente, la interfaz del bridge no se llama "birdge-iptv-2", sino "bridge-iptv"

Saludos!
 
¿De qué router es el pantallazo que me enseñas? ¿Paco o Pepe? Entiendo que es Paco y, si lo es, meter un segundo bridge no tiene sentido (pregúntate, ¿qué comunicaría o puentearía ese bridge). Si estoy equivocado y ese pantallazo es de otro equipo, dime.

Saludos!
 
Es Paco, perdona la ignorancia.
Pero como hemos creado otro túnel eoip y otro wireguard entendia que iría asociado a otro Bridge, quiero buscar el motivo por el que no me funciona y pensé que era por eso.
Gracias por tu ayuda.
Salu2;)
 
Arriba