Delegación de prefijos IPv6 en DIGI

Hola amig@s,

Debido a que en internet hay muy poca información al respecto, os dejo la configuración necesaria para transferir el IPv6 nativo que ofrece DIGI. Hasta ahora sólo se había visto con el propio router de la compañía, ZTE H298A, y en los routers Asus tanto en el sw oficial y en las versiones de tomato firmware.

Lo he probado tanto en el modelo hAP Ac2 como en RB750Gr3 y funciona igual que en el de DIGI, teniendo direcciones IPv6 diferentes en todos los hosts de la LAN y accediendo a Internet.

1.- En primer lugar, hay que activar el paquete IPv6 en el router que por defecto viene desactivado.

2.- Metemos los siguientes comandos por Terminal:

Creamos un interfaz específico en ND
IPv6 - ND (Neighbor Discovery)

Bash:
# En "add interface" pones el nombre que le has dado a tu interfaz Bridge.
/ipv6 nd
set [ find default=yes ] disabled=yes hop-limit=64 other-configuration=yes
add interface=bridge

Creamos un cliente DHCP
IPv6 - DHCP Client

Bash:
# En "interface" pones el nombre de tu interfaz PPPoE que creaste.
# En "pool-name" le das el nombre que desees al Pool de IPv6 que se creará automáticamente al obtener el Prefijo.
# En "interface" dentro del script, pones el nombre que le has dado a tu interfaz Bridge.
# En "from-pool" dentro del script, pones el nombre que le has dado en "pool-name".
/ipv6 dhcp-client
add add-default-route=yes interface=pppoe-out1 pool-name=pool6 request=prefix script=\
    ":delay 5s;\r\
    \n/ipv6 address remove [find advertise=yes] \r\
    \n/ipv6 address add interface=bridge address=::1/64 from-pool=pool6 advertise=yes"

Creamos las siguientes reglas de Firewall IPv6
IPv6 - Firewall - Filter Rules

Bash:
# En "in-interface" y "out-interface" pones el nombre de tu interfaz PPPoE que creaste, en mi caso "pppoe-out1".
/ipv6 firewall filter
add action=drop chain=input comment="Drop (invalid)" connection-state=invalid
add action=accept chain=input comment="Accept (established, related)" connection-state=established,related
add action=accept chain=input comment="Accept DHCP (10/sec)" in-interface=pppoe-out1 limit=10,20:packet protocol=udp src-port=547
add action=drop chain=input comment="Drop DHCP (>10/sec)" in-interface=pppoe-out1 protocol=udp src-port=547
add action=accept chain=input comment="Accept external ICMP (10/sec)" in-interface=pppoe-out1 limit=10,20:packet protocol=icmpv6
add action=drop chain=input comment="Drop external ICMP (>10/sec)" in-interface=pppoe-out1 protocol=icmpv6
add action=accept chain=input comment="Accept internal ICMP" in-interface=!pppoe-out1 protocol=icmpv6
add action=drop chain=input comment="Drop external" in-interface=pppoe-out1
add action=reject chain=input comment="Reject everything else"
add action=accept chain=output comment="Accept all"
add action=drop chain=forward comment="Drop (invalid)" connection-state=invalid
add action=accept chain=forward comment="Accept (established, related)" connection-state=established,related
add action=accept chain=forward comment="Accept external ICMP (20/sec)" in-interface=pppoe-out1 limit=20,50:packet protocol=icmpv6
add action=drop chain=forward comment="Drop external ICMP (>20/sec)" in-interface=pppoe-out1 protocol=icmpv6
add action=accept chain=forward comment="Accept internal" in-interface=!pppoe-out1
add action=accept chain=forward comment="Accept outgoing" out-interface=pppoe-out1
add action=drop chain=forward comment="Drop external" in-interface=pppoe-out1
add action=reject chain=forward comment="Reject everything else"

3.- Una vez finalizado, nos vamos al DHCPv6 Client y en pocos segundos, el Status pasaría de "searching" a "bound". Obteniendo de DIGI un prefijo /56.

1618488248645.png
1618488494234.png


Puede ocurrir que a veces se queda el Status en "searching" y no hay forma de obtener ningún prefijo, esto para mi fue un verdadero quebradero de cabeza y es que DIGI con cada nueva IPv4 te vuelca un prefijo IPv6 nuevo, como es normal, entonces probé lo siguiente: nos vamos a la interfaz PPPoE que tenemos creada y la deshabilitamos, dejamos unos segundos y volvemos habilitarla hasta que sincronice de nuevo.

Ahora ya el DHCPv6 Client ya lo tenemos como "bound" y con un nuevo prefijo. Tras este paso, se crean solos el Pool y el Route List.

4.- Ya solo nos queda, añadir una nueva dirección IPv6 a la interfaz Bridge, con los siguientes datos:

1618493349944.png


Donde ::192.168.88.1/64 es la dirección IP de nuestro Bridge pero en formato IPv6.
Pulsamos en "Apply" y obtenemos del Pool automáticamente el prefijo que recibimos de DIGI.

1618494180684.png


5.- Comprobamos ahora si nuestro PC ha obtenido direcciones IPv6 del router:

1618494590411.png


Y probamos si hay conectividad nativa IPv6

1618494771352.png


1618497050183.png


Pues bien, ya tenemos nuestro Mikrotik funcionando como un proveedor de direcciones SLAAC.

El siguiente video me ha aclarado bastante los pasos a seguir:

Saludos.
 
Última edición:
Wow, magnifico explicado. Imagino sera igual para "todos"./// claro, algunos con PPPoE, otrod client dhcp pero similar
 
Genial, gracias por el tuto! Si te animas, prueba la beta de la V7 que creo que viene ya con IPv6 corriendo por defecto, y esta es su configuración:
Código:
/ipv6 nd
set [ find default=yes ] advertise-dns=yes advertise-mac-address=yes \
    disabled=no dns="" hop-limit=unspecified interface=all \
    managed-address-configuration=no mtu=unspecified other-configuration=no \
    ra-delay=3s ra-interval=3m20s-10m ra-lifetime=30m reachable-time=\
    unspecified retransmit-interval=unspecified
/ipv6 nd prefix default
set autonomous=yes preferred-lifetime=1w valid-lifetime=4w2d
/ipv6 settings
set accept-redirects=yes-if-forwarding-disabled accept-router-advertisements=\
    yes-if-forwarding-disabled disable-ipv6=no forward=yes \
    max-neighbor-entries=8192

Saludos!
 
Última edición:
Hostias compi @diamuxin, qué chasco me he llevado. Curioseando con IPv6 a raíz de tu comentario, me doy cuenta que ni Pepephone (masmóvil) ni O2 (telefónica) están entregando ahora mismo IPv6 en su WAN o_O

Mi gozo en un pozo, me da que me toca esperar para enredar con este tema.

Saludos!
 
Última edición:
Arriba